我的(简化的)输入 XML 如下所示:
<?xml version="1.0" encoding="utf-8"?>
<root>
<recordList>
<record>
<id>16</id>
<MaterialGroup>
<material>
<term>metal, glass</term>
</material>
<material.notes />
<material.part>body</material.part>
</MaterialGroup>
<MaterialGroup>
<material>
<term>wood</term>
</material>
<material.notes>fragile</material.notes>
<material.part>lid</material.part>
</MaterialGroup>
</record>
<record>
...
</record>
</recordList>
</root>
请注意,term
可能包含以逗号分隔的多种 Material 列表(金属、玻璃
)。
所需输出:
我想拆分 Material /术语
,并且需要复制祖级 Material
及其所有属性和节点。
<?xml version="1.0" encoding="utf-8"?>
...
<MaterialGroup>
<material>
<term>metal</term>
</material>
<material.notes />
<material.part>body</material.part>
</MaterialGroup>
<MaterialGroup>
<material>
<term>glass</term>
</material>
<material.notes />
<material.part>body</material.part>
</MaterialGroup>
<MaterialGroup>
<material>
<term>wood</term>
</material>
<material.notes>fragile</material.notes>
<material.part>lid</material.part>
</MaterialGroup>
</record>
...
为分隔孙元素 material/term
中的每个标记复制第一个 MaterialGroup
,并将 term
文本设置为该标记文本。 material.parts
和 material.notes
可以原样复制。
我的样式表:
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
<xsl:output method="xml" indent="yes"/>
<xsl:variable name="separator" select="','"/>
<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="material/term" mode="s">
<xsl:param name="split_term"/>
<xsl:value-of select="$split_term"/>
</xsl:template>
<xsl:template match="MaterialGroup" name="tokenize">
<xsl:param name="text" select="material/term"/>
<xsl:choose>
<xsl:when test="not(contains($text, $separator))">
<xsl:copy>
<xsl:apply-templates/>
<xsl:apply-templates select="material/term" mode="s">
<xsl:with-param name="split_term">
<xsl:value-of select="normalize-space($text)"/>
</xsl:with-param>
</xsl:apply-templates>
</xsl:copy>
</xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:apply-templates/>
<xsl:apply-templates select="material/term" mode="s">
<xsl:with-param name="split_term">
<xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
</xsl:with-param>
</xsl:apply-templates>
</xsl:copy>
<xsl:call-template name="tokenize">
<xsl:with-param name="text" select="substring-after($text, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
实际输出:
<?xml version="1.0" encoding="utf-8"?>
<root>
<recordList>
<record>
<id>16</id>
<MaterialGroup>
<material>
<term>metal, glass</term>
</material>
<material.notes />
<material.part>body</material.part>
metal
</MaterialGroup>
<MaterialGroup>
<material>
<term>metal, glass</term>
</material>
<material.notes />
<material.part>body</material.part>
glass
</MaterialGroup>
<MaterialGroup>
<material>
<term>wood</term>
</material>
<material.notes>fragile</material.notes>
<material.part>lid</material.part>
wood
</MaterialGroup>
</record>
<record>
...
</record>
</recordList>
</root>
标记(metal
、glass
)作为 MaterialGroup
子元素的文本元素出现,位于 material.parts
下方。实际应出现的文本元素 (material/term
) 未更改。
我研究了类似问题的几种解决方案,但没有成功:
https://stackoverflow.com/a/5480198/2044940
https://stackoverflow.com/a/10430719/2044940
http://codesequoia.wordpress.com/2012/02/15/xslt-example-add-a-new-node-to-elements/
...
有什么想法吗?
编辑:马丁的解决方案,没有迈克尔建议的模式:
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="separator" select="', '"/>
<xsl:template match="@* | node()">
<xsl:param name="term"/>
<xsl:copy>
<xsl:apply-templates select="@* | node()">
<xsl:with-param name="term" select="$term"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
<xsl:template match="material/term">
<xsl:param name="term"/>
<xsl:copy>
<xsl:value-of select="$term"/>
</xsl:copy>
</xsl:template>
<xsl:template match="MaterialGroup" name="tokenize">
<xsl:param name="text" select="material/term"/>
<xsl:choose>
<xsl:when test="not(contains($text, $separator))">
<xsl:copy>
<xsl:apply-templates>
<xsl:with-param name="term" select="$text"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:apply-templates>
<xsl:with-param name="term" select="substring-before($text, $separator)"/>
</xsl:apply-templates>
</xsl:copy>
<xsl:call-template name="tokenize">
<xsl:with-param name="text" select="substring-after($text, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
最佳答案
我认为你需要传递你的术语:
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="separator" select="', '"/>
<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="@* | node()" mode="s">
<xsl:param name="term"/>
<xsl:copy>
<xsl:apply-templates select="@* | node()" mode="s">
<xsl:with-param name="term" select="$term"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
<xsl:template match="material/term" mode="s">
<xsl:param name="term"/>
<xsl:copy>
<xsl:value-of select="$term"/>
</xsl:copy>
</xsl:template>
<xsl:template match="MaterialGroup" name="tokenize">
<xsl:param name="text" select="material/term"/>
<xsl:choose>
<xsl:when test="not(contains($text, $separator))">
<xsl:copy>
<xsl:apply-templates mode="s">
<xsl:with-param name="term" select="$text"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:apply-templates mode="s">
<xsl:with-param name="term" select="substring-before($text, $separator)"/>
</xsl:apply-templates>
</xsl:copy>
<xsl:call-template name="tokenize">
<xsl:with-param name="text" select="substring-after($text, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
这样,根据您的输入,我就得到了
<root>
<recordList>
<record>
<id>16</id>
<MaterialGroup>
<material>
<term>metal</term>
</material>
<material.notes/>
<material.part>body</material.part>
</MaterialGroup>
<MaterialGroup>
<material>
<term>glass</term>
</material>
<material.notes/>
<material.part>body</material.part>
</MaterialGroup>
<MaterialGroup>
<material>
<term>wood</term>
</material>
<material.notes>fragile</material.notes>
<material.part>lid</material.part>
</MaterialGroup>
</record>
<record>
...
</record>
</recordList>
</root>
关于xslt - 为孙子中的每个标记复制 node() 并用 XSLT 1.0 中的标记替换孙子的元素文本?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/20955371/