xslt-1.0 - 使用 xsl :value-of in for-each loop over a xsl:variable

Question

这是条目 25317199 中问题的续集.

在 25317199 帖子中，数据有 2 个 block ，即 Schools 和 FamilySmith。 FamilySmith 中的数据用作检索Schools 中数据的 key 。

现在，在这种情况下，数据被拆分，FamilySmith 现在被定义为样式表中的一个变量，如下图所示:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exsl="http://exslt.org/common"
    extension-element-prefixes="exsl"
    version="1.0">

    <xsl:variable name="FamilySmith">
        <Children>
            <Child>
                <Name>Thomas</Name>
                <School_Id>5489</School_Id>
            </Child>
            <Child>
                <Name>Andrew</Name>
                <School_Id>7766</School_Id>
            </Child>
        </Children>
    </xsl:variable>

    <xsl:template match="/Doc">
        <xsl:for-each select="exsl:node-set($FamilySmith)/Children/Child">
            <xsl:text>&#xa;</xsl:text>
            <xsl:value-of select="Name"/>
            <xsl:text> goes to (school's name here) </xsl:text>
            <xsl:value-of select="/Doc/Schools/School[Id = current()/School_Id]/Name"/>
            <xsl:text> at (school's address here) </xsl:text>
            <xsl:value-of select="/Doc/Schools/School[Id = current()/School_Id]/Address"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

这适用于以下 XML 数据:

<Doc>
    <Schools>
        <School>
            <Id>5489</Id>
            <Name>St Thomas</Name>
            <Address>High Street, London, England</Address>
        </School>
        <School>
            <Id>7766</Id>
            <Name>Anderson Boys School</Name>
            <Address>Haymarket, Edinborough</Address>
        </School>
    </Schools>
</Doc>

学校名称和学校地址的检索都产生空字符串，如下所示。

Thomas goes to (school's name here)  at (school's address here) 
Andrew goes to (school's name here)  at (school's address here) 

我已经使用了上一篇文章中给出的建议 25317199 ，即，使用 current() 来识别“来自谓词外部的当前上下文节点”。但似乎问题出在别处。请指教。非常感谢。

Answer 1

问题在于，以 / 开头的绝对路径解析为相对于包含当前上下文节点的树 的根节点，这不一定是输入 XML 文档。里面

<xsl:for-each select="exsl:node-set($FamilySmith)/Children/Child">

路径 /Doc/Schools 正在从 $FamilySmith 派生的临时文档中寻找 Doc 元素(所以 value-of 指令不选择任何内容)。您需要将 for-each 外部的上下文节点保存在另一个变量中:

<xsl:template match="/Doc">
    <xsl:variable name="doc" select="." />
    <xsl:for-each select="exsl:node-set($FamilySmith)/Children/Child">
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of select="Name"/>
        <xsl:text> goes to (school's name here) </xsl:text>
        <xsl:value-of select="$doc/Schools/School[Id = current()/School_Id]/Name"/>
        <xsl:text> at (school's address here) </xsl:text>
        <xsl:value-of select="$doc/Schools/School[Id = current()/School_Id]/Address"/>
    </xsl:for-each>
</xsl:template>