我有三个表:Table1 (AF)、Table2 (MC) 和 Table3 (SC)
我目前对这些表有一个查询,如下所示:
SELECT
AF.[Product Number],
AF.[Week End Date],
AF.[Inv Change Cost],
AF.[Gross Sales Lbs],
AF.[Production Lbs],
MC.[Actual Usage Cost] AS MeatCost,
SC.[Actual Usage Cost] AS SeasonCost
FROM Table1 AF
FULL JOIN Table2 MC ON MC.[Product Number] = AF.[Product Number] AND MC.[Week Ending Date] = AF.[Week End Date]
FULL JOIN Table3 SC ON SC.[Product Number] = AF.[Product Number] AND SC.[Week Ending Date] = MC.[Week Ending Date]
WHERE
AF.[Product Number] = '96443' AND
AF.[Week End Date] = '2/4/2017' AND
MC.[Rout Line Name] = 'Total Cost' AND
SC.[Rout Line Name] = 'Total Cost'
返回以下内容:
Prod # | WE Date | IC Cost | Gross Sales | Prod Lbs | Meat Cost | Season Cost |
96443 2/4/2017 -123456 1000 2000 5000 10000
96443 2/4/2017 -123456 1000 2000 5000 20000
96443 2/4/2017 -123456 1000 2000 6000 10000
96443 2/4/2017 -123456 1000 2000 6000 20000
但是,我希望能够对肉类和季节进行求和,以便表格如下所示:
Prod # | WE Date | IC Cost | Gross Sales | Prod Lbs | Meat Cost | Season Cost |
96443 2/4/2017 -123456 1000 2000 11000 30000
我已经尝试了以下语句,但我得到了所有四个记录的两个总和的总和,这不是我想要返回的值:
SELECT
AF.[Product Number],
AF.[Week End Date],
AF.[Inv Change Cost],
AF.[Gross Sales Lbs],
AF.[Production Lbs],
SUM(MC.[Actual Usage Cost]) AS MeatCost,
SUM(SC.[Actual Usage Cost]) AS SeasonCost
FROM Table1 AF
JOIN Table2 MC ON MC.[Product Number] = AF.[Product Number] AND MC.[Week Ending Date] = AF.[Week End Date]
JOIN Table3 SC ON SC.[Product Number] = AF.[Product Number] AND SC.[Week Ending Date] = MC.[Week Ending Date]
WHERE
AF.[Product Number] = '96443' AND
AF.[Week End Date] = '2/4/2017' AND
MC.[Rout Line Name] = 'Total Cost' AND
SC.[Rout Line Name] = 'Total Cost'
GROUP BY
AF.[Product Number],
AF.[Week End Date],
AF.[Inv Change Cost],
AF.[Gross Sales Lbs],
AF.[Production Lbs];
返回结果:
Prod # | WE Date | IC Cost | Gross Sales | Prod Lbs | Meat Cost | Season Cost |
96443 2/4/2017 -123456 1000 2000 22000 60000
我是否需要对所有字段求和才能获得所需的结果?
更新:
我尝试过这个声明:
SELECT
AF.[Product Number],
AF.[Week End Date],
AF.[Inv Change Cost],
AF.[Gross Sales Lbs],
AF.[Production Lbs],
MC.MeatCost,
SC.SeasonCost
FROM Table1 AF
JOIN(
SELECT [Product Number], [Week Ending Date], SUM([Actual Usage Cost]) AS MeatCost
FROM Table2
GROUP BY [Product Number], [Week Ending Date]
)MC ON
AF.[Product Number] = MC.[Product Number] AND
AF.[Week End Date] = MC.[Week Ending Date]
JOIN(
SELECT [Product Number], [Week Ending Date], SUM([Actual Usage Cost]) AS SeasonCost
FROM Table3
GROUP BY [Product Number], [Week Ending Date]
)SC ON
SC.[Product Number] = MC.[Product Number] AND
SC.[Week Ending Date] = MC.[Week Ending Date]
WHERE
AF.[Product Number] = '96443' AND
AF.[Week End Date] = '2/4/2017';
但是,我得到了与之前尝试相同的结果。
最佳答案
使用这个例子并尝试这样的事情......
CREATE TABLE #Table1 (id INT IDENTITY(1,1), ProdNum INT, WeekEndDate DATETIME, InvChangeCost NUMERIC(18,2), GrossSales NUMERIC(18,2), ProductionLibs NUMERIC(18,2))
INSERT INTO #Table1( ProdNum ,WeekEndDate ,InvChangeCost ,GrossSales ,ProductionLibs)
VALUES(96443, '2/4/2017', -123456, 1000, 2000)
CREATE TABLE #Table2 (id INT IDENTITY(1,1), ProdNum INT, WeekEndDate DATETIME, MeatCost NUMERIC(18,2))
INSERT INTO #Table2( ProdNum ,WeekEndDate ,MeatCost)
VALUES(96443, '2/4/2017', 5000)
INSERT INTO #Table2( ProdNum ,WeekEndDate ,MeatCost)
VALUES(96443, '2/4/2017', 6000)
CREATE TABLE #Table3 (id INT IDENTITY(1,1), ProdNum INT, WeekEndDate DATETIME, SeasonCost NUMERIC(18,2))
INSERT INTO #Table3( ProdNum ,WeekEndDate ,SeasonCost)
VALUES(96443, '2/4/2017', 1000)
INSERT INTO #Table3( ProdNum ,WeekEndDate ,SeasonCost)
VALUES(96443, '2/4/2017', 2000)
SELECT t1.*
, t2.MeatCost
, t3.SeasonCost
FROM #Table1 t1
JOIN (
SELECT ProdNum, WeekEndDate, SUM(MeatCost) AS MeatCost
FROM #Table2
GROUP BY ProdNum, WeekEndDate
)t2 ON
t1.ProdNum = t2.ProdNum AND
t1.WeekEndDate = t2.WeekEndDate
JOIN (
SELECT ProdNum, WeekEndDate, SUM(SeasonCost) AS SeasonCost
FROM #Table3
GROUP BY ProdNum, WeekEndDate
)t3 ON
t3.ProdNum = t2.ProdNum AND
t3.WeekEndDate = t2.WeekEndDate
DROP TABLE #Table1
DROP TABLE #Table2
DROP TABLE #Table3
关于sql-server - SUM 和 JOIN 显示在一条记录中,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/42255248/