c++ - 如何阻止 g++ 链接不需要的异常处理代码？

Question

我正在使用为 arm-eabi 编译的 GCC/G++ 开发嵌入式应用程序。由于资源限制，我试图禁用标准 C++ 异常处理。我正在用“-fno-exceptions”编译代码 -nostartfiles -ffreestanding”。

当一个类的全局实例存在，并且该类包含另一个类的实例作为成员时，就会链接到很多异常处理代码。这不会太糟糕，除了它也带来了在很多 stdio 的东西中，比如 printf、fopen、fclose 和其他 FILE 函数。此应用程序没有文件系统，即使有，这些函数也会浪费太多代码空间。

我知道，即使使用 -fno-exceptions，G++ 也会在使用异常的 operator new 中链接，因为该库没有不使用异常的 operator new(new(nothrow) 除外)。我为 operator new 和 delete 创建了替换项，并将它们链接到输出以及不需要的标准库函数中。

令我困惑的是我没有在任何地方调用 new 。只有当一个全局对象包含另一个对象时，所有这些代码才链接进来。

例如:

class UartA {
...
private:
  Ringbuffer* rxbuf;
};

class UartB {
...
private:
  Ringbuffer rxbuf;
};

如果创建了 UartA 的全局实例，则不会链接异常处理、operator new 和 stdio 内容。这就是我想要的。

如果创建了 UartB 的全局实例(其中 rxbuf 是一个实例而不是指针)，则链接了不需要的代码。

UartA 和 UartB 都不使用 operator new、exceptions 或 stdio。它们的区别仅在于 rxbuf 的类型。

你能建议如何防止链接额外的代码吗？另外，为什么这是为 UartB 而不是 UartA 链接的？

Answer 1

因为您基本上是在做操作系统开发人员为获得独立的 c 或 c++ 环境而做的事情。您可能只想研究使用自定义链接描述文件。你只需要小心，因为像全局构造函数这样的事情不再自动发生......但你也不会得到任何你没有明确要求的东西(并且编写调用全局构造函数的代码并不难)。这是来 self 的操作系统的链接描述文件。

OUTPUT_FORMAT("elf32-i386")
ENTRY(start)

virt = 0xc0100000; /* 3.1 gig */
phys = 0x00100000; /* 1 meg */

SECTIONS
{ 
    .text virt : AT(phys) 
    {
        code = .; _code = .; __code = .;
        *(.text)
        *(.gnu.linkonce.t*)
        . = ALIGN(4096); 
    }

    .rodata : AT(phys + (rodata - code))
    {
        rodata = .; _rodata = .; __rodata = .;
        *(.rodata*)
        *(.gnu.linkonce.r*)
        __CTOR_LIST__ = .;
        LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2) 
        *(.ctors) 
        LONG(0) 
        __CTOR_END__ = .; 

        __DTOR_LIST__ = .; 
        LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2) 
        *(.dtors) 
        LONG(0) 
        __DTOR_END__ = .; 
        . = ALIGN(4096); 
    }

    .data : AT(phys + (data - code))
    {
        data = .; _data = .; __data = .;    
        *(.data)
        *(.gnu.linkonce.d*)
        . = ALIGN(4096); 
    }

    .tbss : AT(phys + (tbss - code)) 
    {
        tbss = .; _tbss = .; __tbss = .;
        *(.tbss)
        *(.tbss.*)
        . = ALIGN(4096); 
    }

    .bss : AT(phys + (bss - code)) 
    {
        bss = .; _bss = .; __bss = .;
        *(.bss)
        *(.bss.*)
        *(COMMON)
        *(.gnu.linkonce.b*)
        . = ALIGN(4096); 
    }

    end = .; _end = .; __end = .;
}

它可能做的比你需要的更多(将部分对齐到 4k 边界，所有符号都在 > 3GB 标记处)但它是一个很好的起点。

你可以这样使用它:

ld -T link_script.ld *.o -lc -o appname

如果您需要，“-lc”也应该链接到 libc 中。