excel - VBA 从类模块中引发错误(使用 Class_Initialize)失败

Question

我一直在尝试在类模块中实现错误处理，这样我就可以记录用户是否遇到任何错误，以及它发生在哪个模块/类中。

我的方法是在调用子函数中处理错误报告，并在被调用子函数中使用 err.raise 将错误冒泡到调用子函数中。

这对于模块(从模块内调用模块)来说工作正常，但是当我测试从类模块内引发错误时，它给了我错误 #440 自动化错误而不是实际错误(比如 ex 的类型不匹配)。

我将(错误？)归结为在运行 class_Initialize 后由于某种原因未初始化 Err 对象的事实，我使用的是 Excel 2016；应用程序版本 = 16。

例如，以下模块调用类属性:

Option Explicit

Private Sub TestCRef()

On Error GoTo ErrHandlr

    Dim y As New CellRef
    'Call y.SetRef  'normal behavior when Class_Initialize() is commented and this is used instead
    Debug.Print y.CstOrdrNo
    
Exit Sub
ErrHandlr:

    If Err.Source = ThisWorkbook.VBProject.Name Then
        Err.Source = "Module1.TestCRef"
    End If
    
    Dim ErrStr As String
    ErrStr = "Error # " & Str(Err.Number) & ", was generated by :" _
                    & Err.Source & ", Description : " & Err.Description
                    
    Debug.Print (ErrStr)
    
End Sub

类模块(CellRef):

Option Explicit

Public CstOrdrNo As Range
Private x As Integer
    
    
Sub Class_Initialize()

On Error GoTo ErrHandlr

    x = "Bug" 'intentional
    Set CstOrdrNo = ThisWorkbook.Worksheets(1).Range("A1")

Exit Sub
ErrHandlr:
    Err.Raise vbObjectError + 5050, "CellRef.Class_Initialize", "Error While Initializing Class"
End Sub

'Used instead of Class_Initialize
Sub SetRef()
On Error GoTo ErrHandlr

    x = "Bug" 'intentional
    Set CstOrdrNo = ThisWorkbook.Worksheets(1).Range("A1")
    
Exit Sub
ErrHandlr:
    Err.Raise vbObjectError + 5050, "CellRef.SetRef", "Error While Intializing x"
End Sub

第一种情况:Class_Initialize用于设置范围，第一次调用时出错。
预期行为:-错误 # -2147216454，由:CellRef.SetRef 生成，说明:初始化类时出错。
发生了什么:- 错误 # 440，由:Module1.TestCRef 生成，描述:自动化错误。
第二种情况: Class_Initialize 被注释掉，使用 SetRef 代替
行为:预期行为。

Answer 1

如您所知，Class_Initialize 引发错误

440: Automation error

当直接在其中引发任何错误时。

但是 Class_Initialize 可以像任何其他过程一样冒出任何错误。

所以我使用这个范式，我将 Class_Initialize 的代码放入一个新过程 ClassInitialize 并从 Class_Initialize 调用它:

Private Sub Class_Initialize()
    ClassInitialize
End Sub

Private Sub ClassInitialize()
    On Error GoTo Catch

   Any code here ...

Done:
    Exit Sub

Catch:
    Err.Raise ...
End Sub

所以我可以在 ClassInitialize 中提出我需要的任何错误，Class_Initialize 会让它冒泡到它的调用者。

根据您的示例进行调整看起来像这样:

Private Sub Class_Initialize()
    ClassInitialize
End Sub

Private Sub ClassInitialize()
    On Error GoTo ErrHandlr

    x = "Bug" 'intentional
    Set CstOrdrNo = ThisWorkbook.Worksheets(1).Range("A1")

    Exit Sub

ErrHandlr:
    Err.Raise vbObjectError + 5050, "CellRef.Class_Initialize", "Error While Initializing Class"
End Sub

还要注意在 Class_Terminate 中处理运行时错误:

没有本地错误处理程序的类的过程 Class_Terminate 中的运行时错误(无论是否由 Err.Raise 本身引发)会导致无法捕获的运行时带有标准错误处理程序消息框的错误(行为与事件处理程序相同)。

所以在 Class_Terminate 中(就像在事件处理程序中一样)总是必须启用“本地”错误处理程序!

并且由于此错误处理程序无法冒出错误，因此您必须在本地处理 Class_Terminate 中的运行时错误。