arrays - Perl 数组和字符串作为方法参数

Question

我有一个方法，我给出两个参数:一个数组和一个字符串 .问题是当我初始化两个不同的变量时，一个用于数组，一个用于字符串，我在第一个变量中获取数组的第一个元素，在第二个变量中获取第二个元素。我的问题是如何获得一个变量中的整个数组和另一个变量中的字符串？

分析.pm

sub analyze {
    my $self = shift;
    my ($content, $stringToSearch) = @_; 
    # my ($stringToSearch) = @_;
    print "$stringToSearch";
    if (!defined($stringToSearch) or length($stringToSearch) == 0) { die 'stringToSearch is not defined yet! ' }
    foreach my $element ($content) {
        #print "$element";
        my $loc = index($element, $stringToSearch);
        # print "$loc\n";
        given ($stringToSearch) {
            when ($stringToSearch eq "Hi") {
                if ($loc != 0) {
                    print "Searched word is Hi \n"; 
                } else {
                    print "No word found like this one! "
                }
            }
            #when ($stringToSearch == 'ORIENTED_EDGE') {
            #   print 'Searched word is ORIENTED_EDGE';
            #} # Printed out because i dont need it now!
        }
        break; # For testing
    }
}

例子.pm

my @fileContent = ('Hi', 'There', 'Its', 'Me')
my $analyzer = Analyze->new();
$analyzer->analyze(@fileContent, 'Hi');

当我改变$content至 @content它将数组和字符串的所有值放入 @content
我希望有人能够帮助我。我是 Perl 的初学者。提前致谢

Answer 1

您不能将数组传递给 subs(或方法)，只能传递标量列表。像这样，

$analyzer->analyze(@lines, 'Hi');

是一样的

$analyzer->analyze($lines[0], $lines[1], ..., 'Hi');

这意味着以下内容将无法正常工作:

my (@strings, $target) = @_;

Perl 不知道有多少项属于原始数组，因此将它们全部放在 @strings 中。 , 离开 $target不明确的。

解决方案

你可以做你想做的事情如下:

sub analyze {
    my $self = shift;
    my $target = pop;
    my @strings = @_
    for my $string (@strings) {
       ...
    }
}

$analyzer->analyze(@lines, 'Hi')

或者没有不必要的副本:

sub analyze {
    my $self = shift;
    my $target = pop;
    for my $string (@_) {
       ...
    }
}

$analyzer->analyze(@lines, 'Hi')

首先通过目标会更容易。

sub analyze {
    my ($self, $target, @strings) = @_;
    for my $string (@strings) {
       ...
    }
}

$analyzer->analyze('Hi', @lines)

或者没有不必要的副本:

sub analyze {
    my $self = shift;
    my $target = shift;
    for my $string (@_) {
       ...
    }
}

$analyzer->analyze('Hi', @lines)

您还可以传递对数组的引用(以您喜欢的任何顺序)，因为引用是一个标量。

sub analyze {
    my ($self, $target, $strings) = @_;
    for my $string (@$strings) {
       ...
    }
}

$analyzer->analyze('Hi', \@lines)

我会选择倒数第二。它遵循与众所周知的 grep 相同的一般模式。 .

my @matches = grep { condition($_) } @strings;