迄今为止我从 actionscript 中看到的最奇怪的行为,我已经使用 AS 超过 10 年了。
var clip1:MovieCip = new MovieClip();
var clip2:MovieCip = new MovieClip();
var clip3:MovieCip = new MovieClip();
var clip;
var myarray:Array = new Array(clip1, clip2, clip3);
for each (clip in myarray)
{ removeChild(clip);
clip = new mc();
trace(clip.name); }
看起来很简单吧?好吧,出于某种原因,Flash 正在将实例名称更改为 instanceX,其中 X 是一些随机分配的数字,我无法再通过分配的名称调用剪辑,例如,如果我尝试...
clip1.x = 300;
flash 不会抛出错误,但 clip1.x 不会移动到 300。我已经为此工作了几个小时,似乎动画片段实际上仍然存在,但 flash 创建了新的动画片段!请帮忙
最佳答案
您似乎不了解成员名称和实例名称之间的区别。我假设您在时间轴上编写代码,这意味着您在该时间轴表示的 MovieClip 对象内部操作(可能是主时间轴,在这种情况下您在 root 内部操作).
成员 是一个 OOP 词,表示对象的字段(普通数据和对象引用)和方法(绑定(bind)函数)。您可以使用点符号或方括号符号来访问成员:
this['a'] = 10;
trace(this.a); // output: 10
当你在时间轴上编写代码时,当你声明变量或函数时,你实际上是在声明当前MovieClip的字段和方法(分别):
var a:int = 10;
trace(a); // output: 10
trace(this.a); // output: 10
trace(this['a']); // output: 10
请记住,在函数体内声明的变量不是对象成员,而是局部函数变量:
function A():void
{
var a:int = 999;
trace(a); // output: 999
trace(this.a); // output: undefined
}
实例名称是 DisplayObject 类的类成员,在“名称”名称下。
trace(name); // output: instance123
trace(this.name); // output: instance123
trace(this['name']); // output: instance123
关于它的令人困惑的部分是 Flash 自动将预先设计的东西声明为对象成员,成员名称与实例名称相同。因此,如果您放置一些实例名称为 MC1 的 MovieClip,您可以按如下方式处理它:
trace(MC1); // output: [object MovieCip]
trace(this.MC1); // output: [object MovieCip]
trace(this['MC1']); // output: [object MovieCip]
trace(getChildByName("MC1")); // output: [object MovieCip]
trace(this.getChildByName("MC1")); // output: [object MovieCip]
您可以在文件 > 发布设置 > AS3 设置 > 自动声明阶段实例 关闭自动声明选项。如果这样做,输出将不同:
trace(MC1); // output: undefined
trace(this.MC1); // output: undefined
trace(this['MC1']); // output: undefined
trace(getChildByName("MC1")); // output: [object MovieCip]
trace(this.getChildByName("MC1")); // output: [object MovieCip]
此外,自动声明功能有效,让我再次强调一下,仅适用于预先设计的内容。如果您创建任何对象的新实例并将它们addChild(...) 到容器,它不会自动将它们的引用添加为容器 OOP 成员。
然后,它如何影响您的问题。
您调用 clip1.x = 300; 并且没有错误。当然没有。 clip1 成员仍然持有对最初声明和实例化的 var clip1:MovieCip = new MovieClip(); 的引用,并且您从未向该成员重新分配任何内容。因此,您解决了未附加到任何东西的有效 MovieClip,但这对 AS3 或 Flash 平台无关紧要:您正在对有效对象执行有效操作。
如果您想要寻址新创建的实例,您应该通过将它们放入的数组,或通过精心组织的实例名称,或通过将它们的引用分配给各自成员名称的成员来实现:
var clip0:MovieCip = new MovieClip;
var clip1:MovieCip = new MovieClip;
var clip2:MovieCip = new MovieClip;
var clip3:MovieCip = new MovieClip;
var myarray:Array = new Array(clip0, clip1, clip2, clip3);
for (var i:int = 0; i < myarray.length; i++)
{
// You better call the class MC, because lowercase
// class name looks like a variable name.
var aClip:MC = new MC;
// Give it a proper instance name.
aClip.name = "clip" + i;
// Assign it as a member of current object.
this["clip" + i] = aClip;
// Put it to designated place into the Array.
myarray[i] = aClip;
}
现在您可以任意处理它:
trace(clip1); // output: [object MC]
trace(this.clip1); // output: [object MC]
trace(this['clip1']); // output: [object MC]
trace(myarray[1]); // output: [object MC]
trace(getChildByName("clip1")); // output: [object MC]
trace(this.getChildByName("clip1")); // output: [object MC]
关于arrays - 为什么 AS3 在 for 循环中创建新实例?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/51303992/