emacs - 在 Emacs 中自动高亮符号

Question

我正在寻找一种自动突出显示符号的方法，可能使用包 highlight-symbol.el ( link )。

我想知道，有没有办法让所有 (setq ) 的第一个参数会自动高亮吗？

(setq thisshouldbehighlighted 1)

..以及所有使用该符号的后续时间/将被使用。

Answer 1

首先，以下代码基于version 1.2高亮符号。旧版本缺少此功能 highlight-symbol-add-symbol .

基本方法是在缓冲区中搜索“(setq”。实际的正则表达式有点复杂，因为它允许空格并处理 defvar 和 defcustom 。

(defun highlight-all-symbols ()
  (interactive)
  (save-excursion
    (highlight-symbol-mode 1)
    (goto-char (point-min))
    (while (re-search-forward (concat "([ \t\n]*"
                                      "\\_<\\(?:"
                                      "setq\\|defvar\\|defcustom"
                                      "\\)\\_>[ \t\n]*"
                                      "\\(\\_<\\(?:\\sw\\|\\s_\\)+\\_>\\)")
                              nil t)
      (highlight-symbol-add-symbol (concat "\\_<"
                                           (regexp-quote (match-string 1))
                                           "\\_>")))))

您可能希望将代码包含在 mode hook 中。

 (add-hook 'emacs-lisp-mode-hook 'highlight-all-symbols)

当然，只需突出显示所有用 setq 设置的符号不能是一个完美的解决方案，因为它忽略了变量命名空间。然而，正确处理这个是一项更大的任务，因为它需要解析代码。如果你想进入那个兔子洞，this可能会给你一个想法，但恐怕它没有特别记录。