templates - D 中的结构体和元组模板参数

Question

是否可以编写一个模板函数来增加不同结构的(数字)字段？例如:

struct Color
{
    ubyte a,r,g,b;
}

struct Point
{
    double x, y;
}

我尝试过这样的事情:

T update(T, A)(T t, A a)
if (is(T == struct))
{
    auto vals = t.tupleof;
    foreach (i; 0 .. vals.length) {
        vals[i] += a; // error: i cannot be read at compile time
    }
    return T(vals); // convert back to struct
}

我还尝试编写接受元组的函数模板，但元组始终会扩展，这会阻止编译器匹配正确的模板。 谢谢。

Answer 1

嗯，我想说你正在尝试做的事情相当奇怪，但这当然是可能的。最天真的、就地的方式可能是:

void update(T)(ref T t)
    if(is(T == struct))
{
    foreach(ref var; t.tupleof)
        ++var;
}

使用副本执行此操作的最简单方法可能是复制它，然后更新它，而不是尝试使用更新的值构造一个新副本(尽管我确信如果您真的想要的话，也可以这样做):

T update(T)(T t)
    if(is(T == struct))
{
    auto copy = t;

    foreach(ref var; copy.tupleof)
        ++var;

    return copy;
}

当然，这里的主要问题是对这两者的模板约束太弱。您所要做的就是在结构中具有不可递增的类型，这是行不通的。解决这个问题的最简单方法可能是创建一个同名模板来为您进行测试:

T update(T)(T t)
    if(isIncrementableStruct!T)
{
    auto copy = t;

    foreach(ref var; copy.tupleof)
        ++var;

    return copy;
}

template isIncrementableStruct(T)
{
    enum isIncrementableStruct = is(T == struct) &&
                                 is(typeof({T t; foreach(var; t.tupleof) ++var;}));
}

如果您希望能够递增所有可递增的字段并保留其他字段，您可能会执行以下操作:

T update(T)(T t)
    if(is(T == struct))
{
    auto copy = t;

    foreach(ref var; copy.tupleof)
    {
        static if(canIncrement!(typeof(var)))
            ++var;
    }

    return copy;
}

template canIncrement(T)
{
    enum canIncrement = is(typeof({T var; ++var;}));
}

无论如何，您似乎错过的主要事情是在使用 ref 时尝试直接迭代 tupleof ，以便更新元素而不是拥有副本其中正在更新。