python - 使用延迟屏幕空间贴花系统的边界检查问题

Question

我正在尝试使用 OpenGL 实现延迟屏幕空间贴花系统，这是一篇名为“使用延迟屏幕空间贴花在其他事物上绘制事物”的文章，链接:http://martindevans.me/game-development/2015/02/27/Drawing-Stuff-On-Other-Stuff-With-Deferred-Screenspace-Decals/ .

在场景顶部绘制了一个红色阴影立方体，该立方体与深度 mask 设置为 false 的墙壁一致。 图片链接(无界立方体):https://gyazo.com/8487947bd4afb08d8d0431551057ad6f

来自墙的深度缓冲区与一些顶点着色器输出一起用于计算立方体维度内墙的对象空间位置。边界检查确保立方体的每个像素都在对象空间位置之外墙被丢弃。

问题是边界没有正常工作，立方体完全消失了。

潜在故障

我已经通过在 lighthitingpass 中可视化深度缓冲区来检查它是否正常工作，它似乎工作正常。深度缓冲区存储在 gbuffer 中的颜色附件中， float 大小为 GL_RGB32F。 图片链接(远处墙壁的 Ligtingpass 深度缓冲可视化):https://gyazo.com/69920a532ca27aa9f57478cb57e0c84c

贴花着色器代码

顶点着色器

// Vertex positions    
vec4 InputPosition = vec4(aPos, 1);   

// Viewspace Position    
PositionVS = view* model* InputPosition;    

// Clipspace Position    
PositionCS = projection*PositionVS;

gl_Position = PositionCS;    

片段着色器

// Position on the screen    
vec2 screenPos = PositionCS.xy / PositionCS.w;

// Convert into a texture coordinate   
vec2 texCoord = vec2((1 + screenPos.x) / 2 + (0.5 / resolution.x), (1 - 
screenPos.y) / 2 + (0.5 / resolution.y));

// Sampled value from depth buffer   
vec4 sampledDepth = texture(gDepth, texCoord);

// View-direction   
vec3 viewRay = PositionVS.xyz * (farClip / -PositionVS.z);

// Wallposition in view-space   
vec3 viewPosition = viewRay*sampledDepth.z;

// Transformation from view-space to world-space   
vec3 WorldPos = (invView*vec4(viewPosition, 1)).xyz;

// Transformation from world-space to object-space   
vec3 objectPosition = (invModel*vec4(WorldPos, 1)).xyz;

// Bounds check, discard pixels outside the wall in object-space    
if (abs(objectPosition.x) > 0.5) discard;    
else if (abs(objectPosition.y) > 0.5) discard;    
else if (abs(objectPosition.z) > 0.5) discard;    

// Color to Gbuffer    
gAlbedoSpec = vec4(1, 0, 0, 1);

代码说明

invView 和 invModel 分别是 View 矩阵和模型矩阵的逆矩阵。矩阵逆计算在 CPU 中完成，并作为制服发送到片段着色器。 farClip 是到相机远平面的距离(这里设置为 3000)。 gDepth 是 Gbuffer 的深度纹理。

问题

与立方体一致的墙部分应为红色阴影，如下图所示，显然不是。

图像链接(带边界的立方体):https://gyazo.com/ab6d0db2483a969db932d2480a5acd08

我的猜测是问题是如何将视空间位置转换为对象空间位置，但我想不通!

Answer 1

您混淆了粉笔和奶酪。 PositionCS 是剪辑空间位置，可以通过 Perspective divide 转换为规范化设备空间位置。 :

vec2 ndcPos = PositionCS.xyz / PositionCS.w;

sampledDepth 是一个深度值(默认在 [0, 1] 范围内)，可以通过读取“红色”颜色 channel (.r , .x) 来自深度缓冲纹理。深度可以通过depth*2.0-1.0转换为规范化的设备空间Z坐标:

vec2 texCoord = ndcPos.xy * 0.5 + 0.5; 
   // (+ 0.5/resolution.xy;) is not necessary if texture filter is GL_NEAREST

float sampledDepth = texture(gDepth, texCoord).x;

float sampleNdcZ = sampledDepth * 2.0 - 1.0;

在透视投影和归一化设备空间中，所有具有相同 x 和 y 坐标的点都在同一条射线上，该射线从 View 位置开始。

这意味着如果深度缓冲区 gDepth 是使用与 ndcPos (PositionCS) 相同的 View 矩阵和投影矩阵生成的，则您可以用相应的 NDC z 坐标替换 ndcPos.z 形成深度缓冲区 (sampleNdcZ)，并且该点仍在同一 View 射线上。
ndcPos.z 和 sampleNdcZ 是同一引用系统中的可比较值。

vec3 ndcSample = vec3(ndcPos.xy, sampleNdcZ);

该坐标可以通过逆投影矩阵和透视划分转换为视空间坐标。
如果 NDC 点，在同一个 View 射线上，被转换到 View 空间，那么 XY 坐标将不同。请注意，由于 (* 1/.w)，转换不是线性的。另见 OpenGL - Mouse coordinates to Space coordinates .

uniform mat4 invProj; // = inverse(projection)

vec4 hViewPos     = invProj * vec4(ndcSample, 1.0);
vec3 viewPosition = hViewPos.xyz / hViewPos.w;

这可以通过逆 View 矩阵到世界空间和逆模型矩阵到对象空间进一步转换:

vec3 WorldPos       = (invView * vec4(viewPosition, 1.0)).xyz;
vec3 objectPosition = (invModel * vec4(WorldPos, 1.0)).xyz;

---