c++ - 贝塞尔曲线评估

Question

我在这里使用 de Casteljau 的算法关注这篇论文 http://www.cgafaq.info/wiki/B%C3%A9zier_curve_evaluation我尝试使用主题 Drawing Bezier curves using De Casteljau Algorithm in C++ , OpenGL帮助。没有成功。

评估时我的贝塞尔曲线看起来像这样

如您所见，尽管它没有像我希望的那样工作，但所有的点确实都在曲线上。由于这个原因，我不认为该算法不准确。

这是我在该图像顶部曲线上的点: (0,0) (2,0) (2,2) (4,2) 第二条曲线使用相同的一组点，只是第三点是(0,2)，即比第一点高两个单位，形成更陡峭的曲线。

出了点问题。我应该为 t 输入 0.25，它应该为 X 值输出 1.0，而 .75 应该总是返回 3。假设 t 是时间。它应该以恒定的速度进步，是吗？恰好在 25% 处，X 值应为 1.0，然后 Y 应与该值相关联。

是否有任何适当的方法来评估贝塞尔曲线？有谁知道这里发生了什么？

感谢您的帮助! :)

编辑------

我在谷歌搜索中找到了这本书 http://www.tsplines.com/resources/class_notes/Bezier_curves.pdf这是我在显式/非参数贝塞尔曲线上找到的页面。它们是表示为贝塞尔曲线的多项式，这就是我在这里要做的。这是书中的那一页:

有人知道如何将贝塞尔曲线转换为参数曲线吗？我现在可以打开一个不同的线程...

自 2011 年 11 月 1 日起再次编辑--------

我意识到我只问了我应该问清楚的问题的一半。我正在尝试构建的是像 Maya 的动画图形编辑器这样的 http://www.youtube.com/watch?v=tckN35eYJtg&t=240其中用于修改曲线的贝塞尔曲线控制点更像是等长的切线修改器。老实说，我不记得它们是等长的。通过强制这样的系统，您可以 100% 确保结果是一个函数并且不包含重叠的段。

我找到了这个，里面可能有我的答案http://create.msdn.com/en-US/education/catalog/utility/curve_editor

Answer 1

在这里您可以看到在 the nomenclature in your link 之后在 Mathematica 中实现的算法，以及你的两个地 block :

(*Function Definitions*)

lerp[a_, b_, t_] := (1 - t) a + t b;
pts1[t_] := {
   lerp[pts[[1]], pts[[2]], t],
   lerp[pts[[2]], pts[[3]], t],
   lerp[pts[[3]], pts[[4]], t]};
pts2[t_] := {
   lerp[pts1[t][[1]], pts1[t][[2]], t],
   lerp[pts1[t][[2]], pts1[t][[3]], t]};
pts3[t_] := {
   lerp[pts2[t][[1]], pts2[t][[2]], t]};

(*Usages*)

pts = {{0, 0}, {2, 0}, {2, 2}, {4, 2}};
Framed@Show[ParametricPlot[pts3[t], {t, 0, 1}, Axes -> True], 
            Graphics[{Red, PointSize[Large], Point@pts}]]

pts = {{0, 0}, {2, 0}, {0, 2}, {4, 2}};
Framed@Show[ParametricPlot[pts3[t], {t, 0, 1}, Axes -> True], 
            Graphics[{Red, PointSize[Large], Point@pts}]]

顺便说一句，曲线由以下参数方程定义，它们是上面代码中的函数 pts3[t]:

c1[t_] := {2 t (3 + t (-3 + 2 t)), (* <- X component *)
                 2 (3 - 2 t) t^2}  (* <- Y component *)

和

c2[t_] := {2 t (3 + t (-6 + 5 t)), (* <- X component *)
               , 2 (3 - 2 t) t^2}  (* <- Y component *)

尝试绘制它们!

采用任何这些曲线方程，并通过求解三次多项式，在这些情况下您可以得到 y[x] 的表达式，这当然不总是可能的。只是为了让您体验一下，从您获得的第一条曲线(C 语法):

y[x]= 3 - x - 3/Power(-2 + x + Sqrt(5 + (-4 + x)*x),1/3) + 
              3*Power(-2 + x + Sqrt(5 + (-4 + x)*x),1/3)

Try plotting it!

编辑

纯属娱乐:

Mathematica 是一种非常强大的函数式语言，事实上整个算法可以用一行代码表示:

f = Nest[(1 - t) #[[1]] + t #[[2]] & /@ Partition[#, 2, 1] &, #, Length@# - 1] &

比如

f@{{0, 0}, {2, 0}, {0, 2}, {4, 2}}

给出了上面的结果，但是支持任意数量的点。

让我们尝试六个随机点:

p = RandomReal[1, {6, 2}];
Framed@Show[
  Graphics[{Red, PointSize[Large], Point@p}],
  ParametricPlot[f@p, {t, 0, 1}, Axes -> True]]

此外，同样的功能在 3D 中也适用:

p = RandomReal[1, {4, 3}];
Framed@Show[
  Graphics3D[{Red, PointSize[Large], Point@p}],
  ParametricPlot3D[f[p], {t, 0, 1}, Axes -> True]]