linux - 如何在 bash 中使用 'while ..; do..; done'

Question

<分区>

Answer 1

首先，awk 和 shell 不共享变量。但是，可以使用 -v 选项将 shell 变量传输到 awk 变量。以下工作正常，对代码的唯一更改是添加 -v line="$line" 选项:

cat namelist | while read line; do awk -v line="$line" '$1 == line {print $0}' Jan.txt; done

请注意，awk 将 line 变量引用为不带美元符号的 line。

上述管道的可能替代品是:

awk 'FNR==NR{a[$1]; next;} $1 in a' namelist Jan.txt

在这里，关联数组 a 跟踪 namelist 中的名称，并使用它来决定是否打印 Jan.txt 中的行。

如果您不打算对数据进行更多处理(但我认为情况恰恰相反)，那么，正如 Shellter 在评论中所建议的那样，上述内容可以替换为:

grep -Ff namelist Jan.txt

如果你想计算 namelist 中用户使用的时间，那么试试:

$ awk -F'[ +:()]+' 'FNR==NR{a[$1]; next;} !($1 in a){next} NF==13{b[$1]+=$12+60*$11} NF==14{b[$1]+=$13+60*($12+24*$11)} END{for (n in b)print n,b[n]}' namelist Jan.txt

例如，考虑这个名单:

$ cat namelist 
sdou
phu

计算的时间是:

$ awk -F'[ +:()]+' 'FNR==NR{a[$1]; next;} !($1 in a){next} NF==13{b[$1]+=$12+60*$11} NF==14{b[$1]+=$13+60*($12+24*$11)} END{for (n in b)print n,b[n]}' namelist Jan.txt
phu 286
sdou 28406

为了可读性，可能更容易看到相同的代码分布在多行中:

awk -F'[ +:()]+' '
  FNR==NR{
    a[$1]
    next
  }

  !($1 in a){
    next
  }

  NF==13{
    b[$1]+=$12+60*$11
  }

  NF==14{
    b[$1]+=$13+60*($12+24*$11)
  }

  END{
    for (n in b)
      print n,b[n]
  }
  ' namelist Jan.txt
phu 286

按用户和按月跟踪使用情况:

$ awk -F'[ +:()]+' 'FNR==NR{a[$1]; next;} !($1 in a){next} NF==13{b[$1"["$4"]"]+=$12+60*$11} NF==14{b[$1"["$4"]"]+=$13+60*($12+24*$11)} END{for (n in b)print n,b[n]}' namelist Jan.txt
phu[Jan] 286
sdou[Jan] 28406