linux - 性能 : How to check processess running on particular cpu

Question

perf 中是否有任何选项可以查看在特定 cpu/core 上运行的进程，以及每个进程占用该核心的百分比。

引用链接会很有帮助。

Answer 1

perf 旨在进行不适合您的情况的分析。您可以尝试对 /proc/sched_debug 进行采样(如果它已在您的内核中编译)。例如，您可以检查哪个进程当前正在 CPU 上运行:

egrep '^R|cpu#' /proc/sched_debug 
cpu#0, 917.276 MHz
R          egrep  2614     37730.177313 ...
cpu#1, 917.276 MHz
R           bash  2023    218715.010833 ...

通过使用他的 PID 作为键，您可以检查它消耗了多少 CPU 时间(以毫秒为单位):

grep se.sum_exec_runtime /proc/2023/sched
se.sum_exec_runtime                          :        279346.058986

---

但是，正如@BrenoLeitão 提到的，SystemTap对您的脚本非常有用。这是您的任务的脚本。

global cputimes;
global cmdline;
global oncpu;

global NS_PER_SEC = 1000000000;

probe scheduler.cpu_on {
    oncpu[pid()] = local_clock_ns();
}

probe scheduler.cpu_off {
    if(oncpu[pid()] == 0)
        next;

    cmdline[pid()] = cmdline_str();
    cputimes[pid(), cpu()] <<< local_clock_ns() - oncpu[pid()];

    delete oncpu[pid()];
}

probe timer.s(1) {
    printf("%6s %3s %6s %s\n", "PID", "CPU", "PCT", "CMDLINE");
    foreach([pid+, cpu] in cputimes) {
        cpupct = @sum(cputimes[pid, cpu]) * 10000 / NS_PER_SEC;

        printf("%6d %3d %3d.%02d %s\n", pid, cpu, 
            cpupct / 100, cpupct % 100, cmdline[pid]);
    }

    delete cputimes;
}

它通过附加到 scheduler.cpu_on 和 scheduler.cpu_off 探测器来跟踪进程在 CPU 上运行和停止执行(由于迁移或休眠)的时刻。第二个探测器计算这些事件之间的时间差，并将其与进程命令行参数一起保存到 cputimes 聚合中。

timer.s(1) 每秒触发一次——它遍历聚合并计算百分比。以下是 Centos 7 的示例输出，bash 运行无限循环:

     0   0 100.16 
    30   1   0.00 
    51   0   0.00 
   380   0   0.02 /usr/bin/python -Es /usr/sbin/tuned -l -P
  2016   0   0.08 sshd: root@pts/0 "" "" "" ""
  2023   1 100.11 -bash
  2630   0   0.04 /usr/libexec/systemtap/stapio -R stap_3020c9e7ba76838179be68cd2390a10c_2630 -F3