windows - 如何限制在单个 Windows session 中运行的应用程序的实例数？

Question

前段时间我问了关于 limiting the number of instances of Excel being run concurrently in Windows 的问题.

感谢我在 StackOverflow.com 上获得的帮助，我能够将以下函数放在一起，如果已经有另一个 Excel 实例在运行，它会关闭任何已启动的 Excel 实例。

Private Function KillDuplicateProcesses() As Boolean

    Dim objWMIService As Object
    Dim colItems As Variant
    Dim objItem As Object
    Dim intCount As Integer

    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Set colItems = objWMIService.InstancesOf("Win32_Process")
    For Each objItem In colItems
        intCount = intCount + Abs(LCase(objItem.Name) = "excel.exe")
        If intCount > 1 Then
            MsgBox "Excel is already running." & vbCrLf & vbCrLf & _
            "To open a file use " & IIf(Application.Version >= 12, "Office Button", "File") & " > Open (Ctrl + O).", vbCritical
            KillDuplicateProcesses = True
            Application.Quit
            Exit For
        End If
    Next

End Function

问题在于，如果用户以管理员身份登录到远程桌面 session ，则该用户帐户可以看到所有其他用户以及他们正在运行的进程。因此，如果另一个用户登录到同一台计算机并正在运行 Excel，该函数也会对这些实例进行计数并关闭刚刚启动的 Excel 实例。

我需要将该函数的范围限制在当前运行的 session 中。根据MSDN documentation有一个名为 SessionID 的类属性。我可以使用该属性并将其与当前 session 的 ID 进行比较以限制函数计数，还是有更好的方法来做到这一点？

如有任何建议，我们将不胜感激。

谢谢!

下面是根据蒂姆建议的解决方案代码。请注意，我将 GetOwner 属性与 Environ UserName 和 UserDomain 进行比较。 Environ 被认为是不可靠的，因为它可以由用户更改。

Private Function KillDuplicateProcesses() As Boolean

    Dim objWMIService As Object
    Dim colItems As Variant
    Dim objItem As Object
    Dim intCount As Integer
    Dim strProcessUser As Variant
    Dim strProcessDomain As Variant

    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Process WHERE Name = 'excel.exe'")

    If colItems.Count > 1 Then

        For Each objItem In colItems

            strProcessUser = ""
            strProcessDomain = ""
            objItem.GetOwner strProcessUser, strProcessDomain
            If IsNull(strProcessUser) Then strProcessUser = ""
            If IsNull(strProcessDomain) Then strProcessDomain = ""

            intCount = intCount + Abs(strProcessUser = Environ("UserName") _
                And strProcessDomain = Environ("UserDomain"))
            If intCount > 1 Then
                MsgBox "You cannot run more than one instance of Excel while iTools is activated." & vbCrLf & vbCrLf & _
                "To open a file use " & IIf(Application.Version >= 12, "Office Button", "File") & " > Open (Ctrl + O).", vbCritical
                KillDuplicateProcesses = True
                Application.Quit
                Exit For
            End If

        Next

    End If

End Function

Answer 1

'get process owner username and domain
Dim strUser, strDomain
objItem.getOwner strUser, strDomain
MsgBox strUser & ", " & strDomain