windows - 通过批处理文件定期通过电子邮件发送文件

Question

我有一个初学者的问题。我有一台收集数据的远程计算机(业余气象学的东西)。数据每天存储在文本文件中。每个文件均以其日期命名:28_02-2014.txt、01_03_2014.txt 等。

任何人都可以帮我创建一个批处理文件，该文件会以某种方式自动通过电子邮件发送这样的文本文件。甚至可以选择从所有 txt 文件创建 zip 文件。我可以每月删除一次该文件夹，因此即使发送包含 31 个文本文件的 zip 文件也不会影响带宽(大约每月 300kb)。

到目前为止我的问题:

Windows 7

1. 我不知道如何创建一个批处理文件来将所有文件压缩到一个文件夹中。
2. 我不知道如何发送自动电子邮件。任务计划程序不允许输入服务器身份验证(用户/密码)。我只能输入 SMTP 服务器名称，仅此而已。
3. 即使我设法通过任务管理器以某种方式发送电子邮件，我也必须每天创建一个操作，这似乎并不理想。

请问有人可以帮我解决这个问题吗？哪种解决方案更简单:要么从特定文件夹发送最新文件，要么将整个文件夹压缩成一个文件并发送。

Answer 1

XP Pro 及更高版本用于使用 WMIC 的日期例程:

在这一行中 set fileattach="d:\myfolder\%datestamp%.txt" 更改文件夹，并将日期戳设置为 dd_mm-yyyy 格式，以便文件名应该适合您。

文本文件将被附加但不会被压缩。

在 set 语句 block 中更改服务器设置和密码以适合您，并进行测试。

如果适合您，您可以按每日周期安排批处理文件。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%DD%_%MM%-%YYYY%"
:: email.bat :::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off
setlocal

:: use these settings to send from a gmail account
:: set port=465 and set SSL=True

:: use these settings for standard email SMTP port and no encryption
:: set port=25 and set SSL=False

:: Change these following items to use the same variables all the time
:: or use the command line to pass all the variables

set Port=25
set SSL=False
set From="<a href="https://stackoverflow.com/cdn-cgi/l/email-protection" class="__cf_email__" data-cfemail="5b36223e363a32371b36223e363a3237283e292d3e2975383436" rel="noreferrer noopener nofollow">[email protected]</a>"
set To="<a href="https://stackoverflow.com/cdn-cgi/l/email-protection" class="__cf_email__" data-cfemail="93e1f6f0fae3faf6fde7d3e0f6e1e5f6e1bdf0fcfe" rel="noreferrer noopener nofollow">[email protected]</a>"
set Subject="Subject line"
set Body="Email Body in one line"
set SMTPServer="mailservername.myemailserver.com"
set User="username"
set Pass="password"
set fileattach="d:\myfolder\%datestamp%.txt"


:: This section sets the command line arguments
:: use this format:  CALL email.bat "<a href="https://stackoverflow.com/cdn-cgi/l/email-protection" class="__cf_email__" data-cfemail="94f9edfaf5f9f1d4f3f9f5fdf8baf7fbf9" rel="noreferrer noopener nofollow">[email protected]</a>" "<a href="https://stackoverflow.com/cdn-cgi/l/email-protection" class="__cf_email__" data-cfemail="ca98afa9a3baa3afa4be8fa7aba3a68baeaeb8afb9b98ab9afb8bcafb8e4a9a5a7" rel="noreferrer noopener nofollow">[email protected]</a>" "Subject line" "Email Body in one line" "smtp.gmail.com"  "<a href="https://stackoverflow.com/cdn-cgi/l/email-protection" class="__cf_email__" data-cfemail="4924302728242c092e24282025672a2624" rel="noreferrer noopener nofollow">[email protected]</a>" "password" "d:\folder\filename to attach.txt"


if "%~7" NEQ "" (
set From="%~1"
set To="%~2"
set Subject="%~3"
set Body="%~4"
set SMTPServer="%~5"
set User="%~6"
set Pass="%~7"
set fileattach="%~8"
)

set "vbsfile=%temp%\email-bat.vbs"
del "%vbsfile%" 2>nul
set cdoSchema=http://schemas.microsoft.com/cdo/configuration
echo >>"%vbsfile%" Set objArgs       = WScript.Arguments
echo >>"%vbsfile%" Set objEmail      = CreateObject("CDO.Message")
echo >>"%vbsfile%" objEmail.From     = %From%
echo >>"%vbsfile%" objEmail.To       = %To%
echo >>"%vbsfile%" objEmail.Subject  = %Subject%
echo >>"%vbsfile%" objEmail.Textbody = %body%
if exist %fileattach% echo >>"%vbsfile%" objEmail.AddAttachment %fileattach%
echo >>"%vbsfile%" with objEmail.Configuration.Fields
echo >>"%vbsfile%"  .Item ("%cdoSchema%/sendusing")        = 2 ' not local, smtp
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpserver")       = %SMTPServer%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpserverport")   = %port%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpauthenticate") = 1 ' cdobasic
echo >>"%vbsfile%"  .Item ("%cdoSchema%/sendusername")     = %user%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/sendpassword")     = %pass%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpusessl")       = %SSL%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpconnectiontimeout") = 30
echo >>"%vbsfile%"  .Update
echo >>"%vbsfile%" end with
echo >>"%vbsfile%" objEmail.Send

cscript.exe /nologo "%vbsfile%"
echo email sent (if variables were correct)
del "%vbsfile%" 2>nul
goto :EOF