windows - TaskDialog 显示中文文本而不是 en-us

Question

我们最近更新了一个内部工具，以使用供应商的在线工具代替我们以前的自制功能。此更新中的一项任务是在用户单击用于执行操作的按钮时将他们重定向到网站。

我想直接在消息框上嵌入一个超链接，因为输入 URL 是非常 1994 年的；但是 MsgBox 不能那样做。有人告诉我 TaskDialog 可以，但它显示的是一堆中文字符，而不是我输入的文本。

我不会说中文，而且我不知道我安装了中文。不管怎样，这个对话框需要显示我输入的英文文本。

请帮忙。

这是我的预期(大致):

下面是我得到的:

这是我用来生成上述内容的代码:

Public Class Form1
    '[DllImport("comctl32.dll", CharSet = CharSet.Unicode,  EntryPoint="TaskDialog")]
    'Static extern int TaskDialog(IntPtr hWndParent, IntPtr hInstance, String pszWindowTitle,
    'String pszMainInstruction, String pszContent, int dwCommonButtons, IntPtr pszIcon, out int pnButton);
    Declare Function TaskDialog Lib "comctl32" Alias "TaskDialog" (
        hWndParent As IntPtr _
        , hInstance As IntPtr _
        , pszWindowTitle As String _
        , pszMainInstruction As String _
        , pszContent As String _
        , dwCommonButtons As Integer _
        , pszIcon As IntPtr _
        , ByRef pnButton As Integer) _
        As Integer

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim b As Integer = 0
        Dim r As Integer = -3

        MsgBox("Use x to process accounts" & vbCrLf &
                "Please visit http://x.u.org:8080/.")
        r = TaskDialog(Me.Handle, IntPtr.Zero,
                       "Account Processing through x",
                       "Use x to process accounts",
                       "Please visit <a href='http://x.u.org:8080/'>http://x.u.org:8080/</a>.",
                       1, UInt16.MaxValue, b)

        MsgBox(String.Format("b:|{0}|; r:|{1}|", b, r))

    End Sub
End Class

最后的调试框显示“b:|1|; r:|0|”。

Answer 1

我认为问题在于您已将 native .NET DllImport 声明转换为 VB6 时代的过时的 Declare Function 声明。通常只要参数正确就可以了，但是 DllImport 声明最好与 .NET 平台调用完全兼容。

在这种情况下，TaskDialog 函数需要 Unicode (UTF-16) 字符串(这由 PCWSTR 中的 W 指示，它代表Wide，如Wide Char)。 Declare Function 语句无法指定要使用的字符集，因此它可能默认为 ANSI - 单字节字符集。

TaskDialog 函数期望每个字符的长度都是两个字节，但它接收到的字符串每个字符只使用一个字节，这使得该函数将每隔一个字符解释为上一个的一部分。这导致相当高的字符代码，恰好映射到 UTF-16 字符表中的中文字符。

如果您查看对话框的蓝色标题，您会发现它显示的字符数仅为实际字符串的一半(“使用 x 处理帐户”)。

解决方案是在 VB.NET 中也使用 DllImport 声明，允许您指定 CharSet.Unicode:

<DllImport("comctl32.dll", CharSet := CharSet.Unicode)> _
Public Shared Function TaskDialog( _
    hWndParent As IntPtr _
    , hInstance As IntPtr _
    , pszWindowTitle As String _
    , pszMainInstruction As String _
    , pszContent As String _
    , dwCommonButtons As Integer _
    , pszIcon As IntPtr _
    , ByRef pnButton As Integer) _
    As Integer
End Function