windows - 计算机重启后恢复批处理脚本

Question

我有一堆运行 Windows 2000 Pro 和 IE 5.0 的旧机器，我想用 Silverlight 升级到 IE 6。我从 Microsoft 的网站下载了 IE6 和 Silverlight 安装程序，幸运的是它们都有命令行选项，允许它们以“静默模式”运行。

我将这两个命令放在 DOS 批处理脚本中并运行了它，但是 IE6 安装程序要求自动重启计算机，所以问题是如何恢复脚本并运行第二个命令(安装 Silverlight)。

我的批处理文件现在非常简单:

ie6setup.exe /Q
silverlight.exe /q

据我所知，批处理文件在重新启动计算机后无法恢复执行。有没有办法让他们这样做？有没有另一种方法来完成我需要的。

谢谢

Answer 1

基于 Tim 的帖子，该帖子在测试时将“two”附加到批处理文件，导致无法找到批处理标签“onetwo”，因此修改为从单独的文本文件读取和写入“current”变量，保持批处理文件不变；

@echo off
call :Resume
goto %current%
goto :eof

:one
::Add script to Run key
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Run /v %~n0 /d %~dpnx0 /f
echo two >%~dp0current.txt
echo -- Section one --
pause
shutdown -r -t 0
goto :eof

:two
echo three >%~dp0current.txt
echo -- Section two --
pause
shutdown -r -t 0
goto :eof

:three
::Remove script from Run key
reg delete HKCU\Software\Microsoft\Windows\CurrentVersion\Run /v %~n0 /f
del %~dp0current.txt
echo -- Section three --
pause
goto :eof

:resume
if exist %~dp0current.txt (
    set /p current=<%~dp0current.txt
) else (
    set current=one
)