windows - 在批处理文件的参数中转义“、<、>、>> 或 | 等字符

Question

尝试做:

fake-command.bat "ping -n 4 -w 1 127.0.0.1 >NUL"

和

fake-command.bat ping -n 4 -w 1 127.0.0.1

批处理文件可能如下所示:

@echo %*

它应该返回:

ping -n 4 -w 1 127.0.0.1 >NUL

和

ping -n 4 -w 1 127.0.0.1

这里有一个解决方法:

@echo off
goto start
------------------------------------------------------

Usage : mystring <command>

  Quotes around the command are required only when the
  command involves redirection via <, >, >>, or |, etc.
  Quotes ensure that the redirection is applied to the 
  command, rather than the bat command itself.

Examples :

  mystring ping -n 4 -w 1 127.0.0.1
  mystring "ping -n 4 -w 1 127.0.0.1 >NUL"

------------------------------------------------------
:start
SETLOCAL ENABLEDELAYEDEXPANSION

SET "MYSTRING=%*"
ECHO My String = !MYSTRING!
SET !MYSTRING=MYSTRING:>=^>!

CALL :BATCH_FUNCTION !MYSTRING!
GOTO :EOF

:BATCH_FUNCTION
SET "ARGS=%~1"
ECHO Arguments = !ARGS!
endlocal
GOTO :EOF

问题是，在:mystring "ping -n 1 127.0.0.1 >NUL"

它返回:

My String =
Arguments =

及之后:mystring ping -n 1 127.0.0.1

它返回:

My String = ping -n 1 127.0.0.1
Arguments = ping

更新: 我用 Get list of passed arguments in Windows batch script (.bat) 中的以下代码更新了问题

@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
if exist param.txt (del param.txt)
for %%a in ('%*') do (
    set "prompt="
    echo on
    for %%b in ('%*') do rem * #%~1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo My string is = !param1!

使用这段代码，我可以获得转义字符，但是如果参数不在引号中，输出就会被破坏

什么有效？

mystring "# % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^ " &REM OK
mystring "ping -n 4 -w 1 127.0.0.1 >NUL" &REM OK

它返回:

My string is = # % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^
My string is = ping -n 4 -w 1 127.0.0.1 >NUL 

什么不起作用？

mystring ping -n 4 -w 1 127.0.0.1 &REM NOK
mystring "*" &REM NOK

它返回:

My string is = ping
The system can not find the file param.txt.
My string is = *

我看不出如何在此代码中添加 the trick from Mofi .

Answer 1

批处理代码也适用于单个参数“ping -n 4 -w 1 127.0.0.1 >NUL”是:

@echo off
goto start
------------------------------------------------------

Usage : mystring <command>

  Quotes around the command are required only when the
  command involves redirection via <, >, >>, or |, etc.
  Quotes ensure that the redirection is applied to the
  command, rather than the bat command itself.

Examples :

  mystring ping -n 4 -w 1 127.0.0.1
  mystring "ping -n 4 -w 1 127.0.0.1 >NUL"

------------------------------------------------------
:start
SETLOCAL ENABLEDELAYEDEXPANSION

if "%~2" == "" (SET "MYSTRING=%~1") else (SET "MYSTRING=%*")
ECHO My String = !MYSTRING!
SET "!MYSTRING=MYSTRING:>=^>!"

CALL :BATCH_FUNCTION "!MYSTRING!"
GOTO :EOF

:BATCH_FUNCTION
SET "ARGS=%~1"
ECHO Arguments = !ARGS!
endlocal
GOTO :EOF

开头的 IF 条件产生了重要的差异。

当批处理文件被调用时

fake-command.bat ping -n 4 -w 1 127.0.0.1

它使用 6 个参数调用，因此 %* 是将所有参数分配给变量 MYSTRING 的正确方法。

但是用

调用批处理文件

fake-command.bat "ping -n 4 -w 1 127.0.0.1 >NUL"

表示只有 1 个用双引号引起来的参数被传递给批处理文件。

线

SET "MYSTRING=%*"

导致将字符串分配给变量 MYSTRING

"ping -n 4 -w 1 127.0.0.1 >NUL"

引号包含在字符串中。剩余的引号会导致进一步处理的错误结果。

尚不清楚应将什么分配给变量 ARGS。如果传递给批处理文件的所有参数都应分配给此变量，则有必要在调用子例程时用双引号将 !MYSTRING! 括起来，以将批处理文件的所有参数作为 1 个参数传递给子程序。

命令 FOR 可用于将分配给 MYSTRING 的字符串拆分为命令 (ping) 及其参数(使用重定向器运算符)。

---

更新(问题更新后):

根本不清楚任务是什么。 This batch code 旨在仅获取传递给批处理文件的第一个参数，这是 #%1# 在第二个内部 FOR 循环中的原因。这正是批处理代码所做的，尽管它包含一个对结果没有影响的小错误。

set "prompt=" 没有效果，因为不可能将提示文本更改为无。所以文件 params.txt 仍然包含提示文本。更好的方法是使用 prompt $_ 或 set "prompt=$_" ，它定义提示文本只是回车 + 换行，因此只产生一个空行，稍后会忽略使用命令 FOR 读取生成的文件 params.txt。在第一个外部 FOR 循环之后，使用 endlocal 恢复先前的提示定义。

Paul ，您刚刚将 (1) 替换为 ('%*') ，这仅对传递给批处理文件的每个参数的第一个和只有第一个参数被写入文本文件params.txt，然后多次读取。使用各种参数运行批处理文件后，只需查看 params.txt 即可查看其中包含的内容。这当然不是很有用。

这里是修改后的批处理代码，以输出传递给批处理文件的所有参数。

@echo off
setlocal DisableDelayedExpansion
del param.txt 2>nul
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (%*) do rem * #%%~b#
    @echo off
) > param.txt
endlocal

setlocal EnableDelayedExpansion
set "ParaNumber=1"
set "AllParameters="
for /F "delims=" %%L in (param.txt) do (
    set "Parameter=%%L"
    set "Parameter=!Parameter:*#=!"
    set "Parameter=!Parameter:~0,-2!"
    set "AllParameters=!AllParameters! !Parameter!"
    echo Parameter !ParaNumber! = !Parameter!
    set /A ParaNumber+=1
)
set "AllParameters=!AllParameters:~1!"
echo All parameters: !AllParameters!
endlocal

依次调用下面三个字符串三次批处理文件

"# % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^ "
"ping -n 4 -w 1 127.0.0.1 >NUL"
ping -n 4 -w 1 127.0.0.1

产生以下三个输出

Parameter 1 = # % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^
All parameters: # % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^

Parameter 1 = ping -n 4 -w 1 127.0.0.1 >NUL
All parameters: ping -n 4 -w 1 127.0.0.1 >NUL

Parameter 1 = ping
Parameter 2 = -n
Parameter 3 = 4
Parameter 4 = -w
Parameter 5 = 1
Parameter 6 = 127.0.0.1
All parameters: ping -n 4 -w 1 127.0.0.1 >NUL

使用 "*" 调用批处理文件现在会导致将当前目录中的所有非隐藏文件列为参数 1 到 n。因此，此批处理文件的修改版本不适用于有效文件名模式的参数。