windows - 使用批处理根据分辨率重命名我的视频文件

Question

我想根据它们的分辨率重命名我的视频文件，例如，对于 1080p 的视频“bla bla.mp4”，我想将其重命名为“bla bla [H.264 1080p]” .该脚本应该能够自动检测视频的分辨率，而且如果文件已经重命名，则不应重命名。我找不到检查分辨率的方法，所以我尝试使用它对于 1080p 文件:

    FOR /r %%a in (*.mp4) DO (IF EXIST *[H.264*.mp4 (
    ECHO Already done) 
    ELSE (
    REN "%%~a" "%%~na [H.264 1080p].mp4"))

但它所做的是一次又一次地检查同一个文件，该文件已经重命名，因此回复总是“已经完成”。

Answer 1

这个问题超出了 SO 问题的范围。不过我会回答的，因为今天是星期天。

• 下载并安装mediainfo命令行版本
• 将 mediainfo 二进制文件的路径添加到您的系统或用户 PATH 环境变量
• 复制重命名脚本，替换你的视频文件夹的路径，rename命令前有一个安全echo，如果输出看起来不错，请将其删除
• 脚本测试已经存在的和已经处理的文件(Peter Wright 建议)

---

重命名脚本:

@echo off & setlocal
cd X:\video\path
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
    set "fnameo=%%~ni"
    set "fnamee=%%~xi"
    set "Height="
    for /f "delims=" %%j in ('mediainfo "--Inform=Video;%%Height%%" "%%~i"') do set "Height=%%j" 
    setlocal enabledelayedexpansion
    call set "selftest=%%fnameo:[H.264 !Height!p]=%%"
    if "!selftest!" equ "!fnameo!" if not exist "!fnameo! [H.264 !Height!p]!fnamee!" (
        echo rename "!fnameo!!fnamee!" "!fnameo! [H.264 !Height!p]!fnamee!"
    )
    endlocal
)

---

输出示例:

rename "Handbrake.0.9.8.mp4" "Handbrake.0.9.8 [H.264 800p].mp4"
rename "Hybrid.2012.10.21.1.mp4" "Hybrid.2012.10.21.1 [H.264 800p].mp4"
rename "Womble.mp4" "Womble [H.264 1080p].mp4"