如果我有一个类型参数约束new()
:
void Foo<T>() where T : new()
{
var t = new T();
}
new T()
是否会在内部使用 Activator.CreateInstance
方法(即反射)?
最佳答案
是的,这是真的。 编辑 2:这里很好地解释了方法和原因。
http://www.simple-talk.com/community/blogs/simonc/archive/2010/11/17/95700.aspx
为了验证我编译了如下方法:
public static T Create<T>() where T: new() {
return new T();
}
这是在 .NET 3.5 SP1 中使用 C# 编译器编译时生成的 IL:
.method public hidebysig static !!T Create<.ctor T>() cil managed
{
.maxstack 2
.locals init (
[0] !!T local,
[1] !!T local2)
L_0000: ldloca.s local
L_0002: initobj !!T
L_0008: ldloc.0
L_0009: box !!T
L_000e: brfalse.s L_001a
L_0010: ldloca.s local2
L_0012: initobj !!T
L_0018: ldloc.1
L_0019: ret
L_001a: call !!0 [mscorlib]System.Activator::CreateInstance<!!T>()
L_001f: ret
}
编辑:C# 4 编译器创建略有不同但相似的代码:
.method public hidebysig static !!T Create<.ctor T>() cil managed
{
.maxstack 2
.locals init (
[0] !!T CS$1$0000,
[1] !!T CS$0$0001)
L_0000: nop
L_0001: ldloca.s CS$0$0001
L_0003: initobj !!T
L_0009: ldloc.1
L_000a: box !!T
L_000f: brfalse.s L_001c
L_0011: ldloca.s CS$0$0001
L_0013: initobj !!T
L_0019: ldloc.1
L_001a: br.s L_0021
L_001c: call !!0 [mscorlib]System.Activator::CreateInstance<!!T>()
L_0021: stloc.0
L_0022: br.s L_0024
L_0024: ldloc.0
L_0025: ret
}
在值类型的情况下,它不使用激活器,而只是返回 default(T)
值,否则它会调用 Activator.CreateInstance
方法。
关于c# - 给定 "where T : new()", "new T()"是否在内部使用 Activator.CreateInstance?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/6708459/