一位同事向我传递了一个有趣的代码示例,该示例在运行时因 InvalidProgramException
(“CLR 检测到无效程序”)而崩溃。
这个问题似乎发生在 JIT 时间,因为它编译得很好,但就在调用带有“违规”行的方法之前抛出异常 - 我猜是因为它正在被 JIT。
有问题的行是调用 Enumerable.ToDictionary
并将 Func
作为第二个参数传递。
如果 Func
参数完全用 lambda 指定,它就可以工作;如果指定为方法组,如果失败。这两者一定是等价的吧?
这让我(以及发现它的同事!)感到难过 - 这看起来确实像是一个 JIT 错误。
[编辑:抱歉 - 我在代码示例中以错误的方式得到了通过和失败的情况 - 现在已更正(上面的描述是正确的)]
谁有解释吗?
using System;
using System.Linq;
internal class Program
{
private static void Main(string[] args)
{
Test.Try();
}
}
public class Test
{
public static readonly int[] integers = new[] { 1, 3, 5 };
public static void Try()
{
var line = new Line { A = 3, B = 5 };
// PASSES
var dict = integers.ToDictionary<int, int, decimal>(i => i, i => line.Compute(i));
// FAILS
//var dict = integers.ToDictionary<int, int, decimal>(i => i, line.Compute);
Console.WriteLine(string.Join(" ", dict.Select(kv => kv.Key + "-" + kv.Value)));
}
}
public class Line
{
public decimal A;
public decimal B;
}
public static class SimpleCompute
{
public static decimal Compute(this Line line, int value)
{
return line.A*value + line.B;
}
}
最佳答案
编译器错误。
有关信息,我有异步 CTP,这可能是相关的; csc
报告:4.0.30319.440
似乎是之间的区别:
public static void TryTwo() // fails
{
var line = new Line {A = 3, B = 5};
var dict = integers.ToDictionary<int, int, decimal>(i => i, line.Compute);
Console.WriteLine("TryTwo complete");
}
public static void TryFive() // works
{
var line = new Line { A = 3, B = 5 };
Func<int, decimal> func = line.Compute;
var dict = integers.ToDictionary<int, int, decimal>(i => i, func);
Console.WriteLine("TryFour complete");
}
让我们看看反射器:
.method public hidebysig static void TryTwo() cil managed
{
.maxstack 4
.locals init (
[0] class Line <>g__initLocal6)
L_0000: newobj instance void Line::.ctor()
L_0005: stloc.0
L_0006: ldloc.0
L_0007: ldc.i4.3
L_0008: newobj instance void [mscorlib]System.Decimal::.ctor(int32)
L_000d: stfld valuetype [mscorlib]System.Decimal Line::A
L_0012: ldloc.0
L_0013: ldc.i4.5
L_0014: newobj instance void [mscorlib]System.Decimal::.ctor(int32)
L_0019: stfld valuetype [mscorlib]System.Decimal Line::B
L_001e: ldsfld int32[] Test::integers
L_0023: ldsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegate8
L_0028: brtrue.s L_003b
L_002a: ldnull
L_002b: ldftn int32 Test::<TryTwo>b__7(int32)
L_0031: newobj instance void [mscorlib]System.Func`2<int32, int32>::.ctor(object, native int)
L_0036: stsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegate8
L_003b: ldsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegate8
L_0040: call class [mscorlib]System.Collections.Generic.Dictionary`2<!!1, !!2> [System.Core]System.Linq.Enumerable::ToDictionary<int32, int32, valuetype [mscorlib]System.Decimal>(class [mscorlib]System.Collections.Generic.IEnumerable`1<!!0>, class [mscorlib]System.Func`2<!!0, !!1>, class [mscorlib]System.Func`2<!!0, !!2>)
L_0045: pop
L_0046: ldstr "TryTwo complete"
L_004b: call void [mscorlib]System.Console::WriteLine(string)
L_0050: ret
}
对比
.method public hidebysig static void TryFive() cil managed
{
.maxstack 4
.locals init (
[0] class Line line,
[1] class [mscorlib]System.Func`2<int32, valuetype [mscorlib]System.Decimal> func,
[2] class Line <>g__initLocal9)
L_0000: newobj instance void Line::.ctor()
L_0005: stloc.2
L_0006: ldloc.2
L_0007: ldc.i4.3
L_0008: newobj instance void [mscorlib]System.Decimal::.ctor(int32)
L_000d: stfld valuetype [mscorlib]System.Decimal Line::A
L_0012: ldloc.2
L_0013: ldc.i4.5
L_0014: newobj instance void [mscorlib]System.Decimal::.ctor(int32)
L_0019: stfld valuetype [mscorlib]System.Decimal Line::B
L_001e: ldloc.2
L_001f: stloc.0
L_0020: ldloc.0
L_0021: ldftn valuetype [mscorlib]System.Decimal SimpleCompute::Compute(class Line, int32)
L_0027: newobj instance void [mscorlib]System.Func`2<int32, valuetype [mscorlib]System.Decimal>::.ctor(object, native int)
L_002c: stloc.1
L_002d: ldsfld int32[] Test::integers
L_0032: ldsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegateb
L_0037: brtrue.s L_004a
L_0039: ldnull
L_003a: ldftn int32 Test::<TryFive>b__a(int32)
L_0040: newobj instance void [mscorlib]System.Func`2<int32, int32>::.ctor(object, native int)
L_0045: stsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegateb
L_004a: ldsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegateb
L_004f: ldloc.1
L_0050: call class [mscorlib]System.Collections.Generic.Dictionary`2<!!1, !!2> [System.Core]System.Linq.Enumerable::ToDictionary<int32, int32, valuetype [mscorlib]System.Decimal>(class [mscorlib]System.Collections.Generic.IEnumerable`1<!!0>, class [mscorlib]System.Func`2<!!0, !!1>, class [mscorlib]System.Func`2<!!0, !!2>)
L_0055: pop
L_0056: ldstr "TryFour complete"
L_005b: call void [mscorlib]System.Console::WriteLine(string)
L_0060: ret
}
如果您查看损坏的版本,它只加载一个委托(delegate)。编译器错误,基本上:
L_0023: ldsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegate8
L_0028: brtrue.s L_003b
L_002a: ldnull
L_002b: ldftn int32 Test::<TryTwo>b__7(int32)
L_0031: newobj instance void [mscorlib]System.Func`2<int32, int32>::.ctor(object, native int)
L_0036: stsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegate8
L_003b: ldsfld class [mscorlib]System.Func`2<int32, int32> Test::CS$<>9__CachedAnonymousMethodDelegate8
L_0040: call class [mscorlib]System.Collections.Generic.Dictionary`2<!!1, !!2> [System.Core]System.Linq.Enumerable::ToDictionary<int32, int32, valuetype [mscorlib]System.Decimal>(class [mscorlib]System.Collections.Generic.IEnumerable`1<!!0>, class [mscorlib]System.Func`2<!!0, !!1>, class [mscorlib]System.Func`2<!!0, !!2>)
以上都是“检查缓存的i => i
是否存在;如果不存在,则加载它”。它对第二个委托(delegate)从不做任何事情。因此,堆栈上没有足够的值来进行方法调用。
关于c# - 将 Enumerable.ToDictionary 与扩展方法一起使用时为 "CLR detected an Invalid Program",我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/9292663/