java - 在 clojure 中同时支持 xml 和 json REST 响应

Question

假设我在 Java 中有一个 REST API，它支持 JSON 或 XML 的响应。响应包含相同的数据，但形式不同。例如，在 json 中我可能有:

{
    "persons": [
        {
            "name":"Bob",
            "age":24,
            "hometown":"New York"
        }
    ]
}

而在 XML 中它看起来像这样:

<persons>
    <person name="bob" age="24">
        <hometown>New York</hometown>
    </person>
</persons>

也就是说有的值是person上的属性，有的是子元素。在 Java 中，使用 JAXB 和 Jackson，可以很容易地通过模型对象上的注释来隐藏这种差异，例如:

public class Person {
    @XmlAttribute
    String name;

    @XmlAttribute
    Integer age;

    @XmlElement 
    String hometown; 
}

JAXB 读取注释，Jackson 使用字段名来确定要做什么。因此，使用单一模型很容易支持多种输出格式。

所以我的问题是，如何在 Clojure 中做同样的事情。我知道有 clj-json 可以轻松地将 clojure 映射和 vector 转换为 json(如果我没记错的话，使用 jackson)。而且我知道 clojure.xml.emit 和 clojure.contrib.xml.prxml 都可以将映射和 vector 反序列化为 XML。但除非我弄错了，否则我认为这两者不会很好地协同工作。

因为prxml期望xml节点表示为vector，xml属性表示为map，这与clj-json的工作方式根本不同，vector表示数组，map表示对象。而 clojure.core.emit 需要一个格式为 {:tag :person :attrs {:name "Bob":age 24} :content ...} 的映射，这又与 clj 完全不同-json 想要。

我唯一能想到的就是在我的代码中格式化prxml的数据结构，然后写一个函数，当响应类型是JSON时，将数据结构转换成clj-json想要的。但这似乎有些蹩脚。如果有一对像 JAXB 和 Jackson 一样兼容的 JSON 和 XML 库，我会更喜欢。

想法？

Answer 1

很大程度上取决于您选择如何在代码中表示模型。

假设您使用记录。这是一个人为的示例，说明您如何“注释”记录并为 XML 和 JSON 提供序列化程序。

;; Depends on cheshire and data.xml
(ns user
  (:require [cheshire.core :as json]
            [clojure.data.xml :as xml]))

(defrecord Person [name age hometown])
(defrecord Animal [name sound])

(def xml-attrs {Person [:name :age]
                Animal [:name]})

(defn record->xml-data [rec]
  (let [tag (-> rec class .getSimpleName .toLowerCase keyword)
        attrs (select-keys rec (xml-attrs (class rec)))
        content (for [[k v] rec
                      :when (not (contains? attrs k))]
                  (xml/element k nil (str v)))]
    (apply xml/element tag attrs content)))

(defn record->xml [rec]
  (xml/emit-str (record->xml-data rec)))

(defn record->json [rec]
  (json/generate-string rec))

用法:

> (def bob (Person. "Bob" 24 "New York"))
#'user/bob

> (println (record->xml bob))
<?xml version="1.0" encoding="UTF-8"?><person age="24" name="Bob"><hometown>New York</hometown></person>
nil

> (println (record->json bob))
{"name":"Bob","age":24,"hometown":"New York"}
nil

> (println (record->xml (Animal. "Fido" "Bark!")))
<?xml version="1.0" encoding="UTF-8"?><animal name="Fido"><sound>Bark!</sound></animal>
nil

可以创建一个宏来在单个语句中定义记录及其 XML 属性。例如，

(defrecord-xml Person [^:xml-attr name ^:xml-attr age hometown])