java - ANTLR @header、@parser、superClass 选项和基本文件 io (Java)

Question

我想对基本文件 io (Java) 使用解析器操作，例如。 G。 ANTLR 语法中的 PrintWriter。我必须使用 superClass 选项还是可以使用 @header？在这两种情况下，我如何声明 PrintWriter 对象以及我必须如何处理异常？

Answer 1

选项 superClass=... 用于让您的 Parser 扩展自定义类。所以，我认为这不是您想要的。

@header 部分中的所有内容都将放在 Parser 类的开头。这用于导入类:

@header {
  import java.io.PrintWriter;
}

请注意，@header {...} 是 @parser::header {...} 的缩写。您还可以为词法分析器定义:@lexer::header {...}。

在 @member {...}(或:@parser::member {...}，@lexer::member {。 ..}) 部分，您可以添加可在 Parser 或 Lexer 中使用的实例变量和方法:

@header {
  import java.io.PrintWriter;
}

@members {
  PrintWriter writer;
}

语法的一个小演示，其解析器将解析后的数字写入特定的编写器:

grammar T;

@header {
  import java.io.PrintWriter;
}

@members {
  PrintWriter writer;

  public TParser(TokenStream input, String fileName) {
    super(input);
    try {
      writer = new PrintWriter(fileName);
    } catch(Exception e) {
      e.printStackTrace();
    }
  }
}

parse
  :  numbers EOF
  ;

numbers
  :  (NUM {
            writer.println("parsed: " + $NUM.text);
            writer.flush();
          }
     )+
  ;

NUM : '0'..'9'+;
WS  : ' ' {skip();};

可以通过以下方式进行测试:

import java.io.File;
import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String source = "42 500000000 666";
    TLexer lexer = new TLexer(new ANTLRStringStream(source));
    TParser parser = new TParser(new CommonTokenStream(lexer), "log.txt");
    parser.parse();
  }
}

如果您运行上面的类，将创建一个名为 log.txt 的文件，其中包含:

parsed: 42
parsed: 500000000
parsed: 666

请注意，所有这些 @... 和 options {...} 等实例都有严格的顺序:

1. 语法定义
2. options block (没有 @ 符号!)
3. tokens block (没有 @ 符号!)
4. @header block
5. @members block

grammar T;

options {
  // options here
}

tokens {
  // imaginary tokens here
}

@header  { 
  // ... 
}

@members { 
  // ... 
}

---

编辑

ANTLRStarter wrote:

How can I add code which is executed at the end of the the lexer/parser class?

没有这样的内置功能。但是您可以在解析器中轻松创建自定义方法 wrapUp():

@members {

  // ...

  private void wrapUp() {
    // wrap up your parser in here
  }
}

然后像这样从语法的入口点自动调用该方法:

parse
@after {this.wrapUp();}
  :  numbers EOF
  ;

当规则中的所有内容都正确匹配时，将执行放置在规则的 @after {...} block 中的任何代码。