lotus-notes - 获取第一个文档，在 Lotus 中不返回任何内容

Question

当我尝试访问当前 View 中所选文档的字段时，我什么也没得到。 我的代码:

Sub Click(Source As Button)
  Dim ws As New NotesUIWorkspace
  Dim uiview As NotesUIView 
  Dim dc As NotesDocumentCollection 
  Dim doc As NotesDocument 
  Dim receive As String 
  Set uiview=ws.CurrentView
  Set dc=uiview.Documents
  Set doc=dc.GetFirstDocument
  If doc Is Not Nothing Then
    receive=doc.GetItemValue("Field name")
  End If
End Sub

它永远不会进入 if，因为 doc 总是什么都没有。当我删除 if 时，当 getitemvalue 尝试获取某些内容但无法获取内容时，会出现错误

Answer 1

dc.GetFirstDocument 不返回任何内容，因为集合为空。如果您没有选择带有复选标记的文档，就会发生这种情况。 uiview.Documents 仅传送那些选定的文档，不传送突出显示的文档。

如果您只想查看突出显示的文档(加框的文档) 那么这将起作用:

Sub Click(Source As Button)
    Dim session As New NotesSession
    Dim doc As NotesDocument
    Set doc = session.DocumentContext
    If Not doc Is Nothing Then
        receive=doc.GetItemValue("FieldName")(0)
        Print receive
    End If
End Sub

session.DocumentContext 返回 View 中突出显示的文档。

如果您想查看所有选定的文档

您可以使用稍微修改过的代码

Sub Click(Source As Button)
    Dim ws As New NotesUIWorkspace
    Dim uiview As NotesUIView
    Dim dc As NotesDocumentCollection
    Dim doc As NotesDocument
    Set uiview = ws.CurrentView
    Set dc = uiview.Documents
    Set doc = dc.GetFirstDocument
    While Not (doc Is Nothing)
        Print doc.GetItemValue ("FieldName")(0)
        Set doc = dc.GetNextDocument (doc)
    Wend
End Sub