sql - 基于不同表的表和表单 - 查看表中是否存在公共(public)记录并在表单中插入 "yes"或 "no"值

Question

我有一个 Access 数据库，我的团队用它来跟踪项目。我们用它作为 VCB。

在主表单(项目)上，我们查看它并在项目表单上进行更新 - 这反过来又更新链接到该表单的表。

但是，我们还有一个单独的表(评论)，用于存储与项目相关的评论。两个表的主键都是 ProjectID。

项目表单上只有 1 个项目条目，但评论表上的评论可以有 0 到多个。

我想要实现的是让项目表单(我们的 VCB)查看注释表，并查看表中是否有具有相同 ProjectID 的记录 - 如果有，请在我的文本框中插入"is"值在项目表格上，但如果没有，则插入“否”。

它只是一个简单的视觉辅助工具，用于查看 VCB 上的项目是否存在评论(我们以单独的形式处理评论输入和查看)

我不知道该走哪条路。我尝试了一些事情，但陷入了循环。任何帮助表示赞赏

Dim strSQL As String
Dim rs As Dao.Recordset
Dim db As Dao.Database

strSQL = "SELECT * FROM COMMENTS WHERE [PROJECTID] = " & Me.PROJECTID & ""

Set db = CurrentDb
Set rs = db.OpenRecordset("COMMENTS")

rs.MoveFirst

Do Until rs.EOF = True
 Set rs = db.OpenRecordset(strSQL)
   If rs.RecordCount = 0 Then
     Me.CommentTxtBox.SetFocus
     Me.CommentTxtBox.Text = "NO"
  Else
     Me.CommentTxtBox.SetFocus
     Me.CommentTxtBox.Text = "YES"
  End If
 rs.MoveLast
Loop

rs.Close
Set rs = Nothing

我在该字段中得到的每个条目都是“否”，并且它出错了，因为 ProjectID 不在评论表中(它可能不在)，所以它说没有找到记录。

Answer 1

DCount() 可以使您的代码更简单。

Dim lngComments As Long
Dim strComments As String

lngComments = DCount("*", "COMMENTS", "[PROJECTID] = " & Me.PROJECTID)
If lngComments > 0 Then
    strComments = "YES"
Else
    strComments = "NO"
End If
Me.CommentTxtBox.Value = strComments

请注意，通过将值分配给文本框的 .Value 属性(而不是其 .Text 属性)，您不必担心 SetFocus .

我认为这是您当前方法的更简单版本。但是我不确定这是否是最好的方法。也许您可以通过将文本框的 Control Source 属性设置为使用 IIf 计算 DCount 的表达式来获得所需的内容:

=IIf(DCount("*", "COMMENTS", "[PROJECTID] = " & [PROJECTID]) > 0, "YES", "NO")