arrays - 为什么这个涉及数组的 Dafny 断言会失败？

Question

我正在研究高斯消除的验证实现，但在验证这个将数组 b 的内容添加到数组 a 的内容的 super 简单方法时遇到问题。这是代码。

method addAssign(a: array<real>, b: array<real>)
   requires a != null && b != null && a.Length == b.Length;
   modifies a
   ensures forall k:: 0 <= k < a.Length ==> a[k] == old(a[k]) + b[k];
{
   var i := 0;
   assert a == old(a);
   while(i < a.Length)
      invariant 0 <= i <= a.Length
      invariant forall k:: i <= k < a.Length ==> a[k] == old(a[k])
      invariant forall k:: 0 <= k < i ==> a[k] == old(a[k]) + b[k];
   {
      assert a[i] == old(a[i]); // dafny verifies this
      a[i] := a[i] + b[i];
      assert a[i] == old(a[i]) + b[i]; // dafny says this is an assertion violation
      i := i + 1;
   }
}

Answer 1

(我删除了我的第一个答案，因为它不起作用)。

问题似乎在于 Dafny 检测到潜在的别名问题。作为一个实验，我首先修改了您的代码以获得一个更简单的函数来验证:

method addOne(a: array<real>)
   requires a != null;
   modifies a;
   ensures forall k:: 0 <= k < a.Length ==> a[k] == old(a[k]) + 1.0;
{
   var i := 0;
   assert a == old(a);
   while(i < a.Length)
      invariant 0 <= i <= a.Length
      invariant forall k:: i <= k < a.Length ==> a[k] == old(a[k])
      invariant forall k:: 0 <= k < i ==> a[k] == old(a[k]) + 1.0;
   {
      assert a[i] == old(a[i]); // dafny verifies this
      a[i] := a[i] + 1.0;
      assert a[i] == old(a[i]) + 1.0; // dafny *doesn't* say this is an assertion violation
      i := i + 1;
   }
}

唯一的区别是我使用的是文字实数 (1.0)，而不是从 b 提取的实数。为什么这会产生影响？

假设您通过如下所示的调用来调用您的方法

addAssign(a,a)

然后在函数体中b和a都引用同一个数组。例如，假设 a[0] 为 1.0。然后在第一次循环中执行 a[0] := a[0] + b[0]。

这会将 a[0] 设置为 2.0。但是 - 它还将b[0]设置为2.0。

但在这种情况下 assert a[0] == old(a[0]) + b[0] 相当于

断言 2.0 == 1.0 + 2.0——应该失败。

顺便说一下——以下确实验证了:

method addAssign(a: array<real>, b: array<real>)
   requires a != null && b != null && a.Length == b.Length;
   modifies a;
   ensures forall k:: 0 <= k < a.Length ==> a[k] == old(a[k]) + old(b[k]);
{
   var i := 0;
   assert a == old(a);
   while(i < a.Length)
      invariant 0 <= i <= a.Length
      invariant forall k:: i <= k < a.Length ==> a[k] == old(a[k])
      invariant forall k:: 0 <= k < i ==> a[k] == old(a[k]) + old(b[k]);
   {
      assert a[i] == old(a[i]); // dafny verifies this
      a[i] := a[i] + b[i];
      assert a[i] == old(a[i]) + old(b[i]); // and also this!
      i := i + 1;
   }
}