regex - Perl Regex - 打印匹配的条件正则表达式

Question

我正在尝试从日志文件中提取一些模式，但无法正确打印它们。

日志字符串示例:

1) sequence_history/buckets/FPJ.INV_DOM_16_PRD.47269.2644?startid=2644000&endid=2644666

2) sequence_history/buckets/FPJ.INV_DOM_16_PRD.41987.9616

我想提取 3 件事:

A = "FPJ.INV_DOM_16_PRD" B = "47269" C = 9616 or 2644666 (if the line has endid then C = 2644666 else it's 9616)

日志行可以是类型 1 或 2。我能够提取 A 和 B，但我被 C 困住了，因为我需要它的条件语句，但我无法正确提取它。我正在粘贴我的代码:

my $string='/sequence_history/buckets/FPJ.INV_DOM_16_PRD.47269.2644?startid=2644000&endid=2644666';

if ($string =~ /sequence_history\/buckets\/(.*)/){
    my $line = $1;
    print "$line\n";
    if($line =~ /(FPJ.*PRD)\.(\d*)\./){
        my $topic_type_string = $1;
        my $topic_id = $2;
        print "$1\n$2\n";

    }
if($string =~ /(?(?=endid=)\d*$)/){
    # how to print match pattern here? 
    print "match\n";
}

提前致谢!

Answer 1

这将完成这项工作:

use Modern::Perl;
use Data::Dumper;

my $re = qr/(FPJ.+?PRD)\.(\d+)\..*?(\d+)$/;
while(<DATA>) {
    chomp;
    my (@l) = $_ =~  /$re/g;
    say Dumper\@l;
}

__DATA__
sequence_history/buckets/FPJ.INV_DOM_16_PRD.47269.2644?startid=2644000&endid=2644666
sequence_history/buckets/FPJ.INV_DOM_16_PRD.41987.9616

输出:

$VAR1 = [
          'FPJ.INV_DOM_16_PRD',
          '47269',
          '2644666'
        ];

$VAR1 = [
          'FPJ.INV_DOM_16_PRD',
          '41987',
          '9616'
        ];

说明:

(       : start group 1
  FPJ   : literally FPJ
  .+?   : 1 or more any character but newline, not greedy
  PRD   : literally PRD
)       : end group 1
\.      : a dot
(       : start group 2
  \d+   : 1 or more digit
)       : end group 2
\.      : a dot
.*?     : 0 or more any character not greedy
(       : start group 3
  \d+   : 1 or more digit
)       : end group 3
$       : end of string