powerquery - 将字符串中的多个单词替换为列表中的特定单词

Question

如何使用 M 语言将字符串中的特定单词替换为表中指定的其他特定单词？

查看我的示例数据:

源代码:

let
    someTable = Table.FromColumns({{"aa &bb &cc dd","&ee ff &gg hh &ii"}, {Table.FromColumns({{"&bb","&cc"}, {"ReplacementForbb", "ccReplacement"}},{"StringToFind", "ReplaceWith"}), Table.FromColumns({{"&ee", "&gg","&ii"}, {"OtherReplacementForee", "SomeReplacementForgg", "Replacingii"}},{"StringToFind", "ReplaceWith"})}, {"aa ReplacementForbb ccReplacement dd","OtherReplacementForee ff SomeReplacementForgg hh Replacingii"}},{"OriginalString", "Replacements", "WantedResult"})
in
    someTable

Answer 1

这是一个很好的问题。您可以使用一些表来执行此操作，并将 M 函数作为自定义列列出，如下所示:

= Text.Combine(
      List.ReplaceMatchingItems(
          Text.Split([OriginalString], " "),
          List.Transform(Table.ToList([Replacements]),
              each Text.Split(_,",")
          )
      ),
  " ")

我将使用第一行作为示例来演示其工作原理。

---

[OriginalString]是 "aa &bb &cc dd"我们使用 Text.Split将其转换为列表。

"aa &bb &cc dd" --Text.Split--> {"aa", "&bb", "&cc", "dd"}

现在我们需要处理 [Replacements]表并将其转换为列表的列表。开头是:

StringToFind  ReplaceWith
------------------------------
&bb           ReplacementForbb
&bb           ccReplacement

使用Table.ToList这将成为一个两个元素的列表(因为该表有两行)。

{"&bb,ReplacementForbb","&cc,ccReplacement"}

使用Text.Split在逗号上，我们可以将每个元素转换成一个列表来得到

{{"&bb","ReplacementForbb"},{"&cc","ccReplacement"}}

这是我们需要的 List.ReplaceMatchingItems 的形式功能。

List.ReplaceMatchingItems(
    {"aa", "&bb", "&cc", "dd"},
    {{"&bb","ReplacementForbb"},{"&cc","ccReplacement"}}
)

这会进行替换并返回列表

{"aa","ReplacementForbb","ccReplacement","dd"}

最后，我们使用Text.Combine将上面的列表连接成一个字符串。

"aa ReplacementForbb ccReplacement dd"