arrays - 在汇编中声明和索引 qword 整数数组

Question

我有一个关于如何在汇编中初始化数组的问题。我尝试过:

.bss
#the array
unsigned:    .skip 10000
.data
#these are the values that I want to put in the array
par4:   .quad 500 
par5:   .quad 10
par6:   .quad 15

这就是我声明字符串和要放入其中的变量的方式。 这就是我尝试将它们放入数组的方法:

movq $0 , %r8

movq par4 , %rax
movq %rax , unsigned(%r8)
incq %r8

movq par5 , %rax
movq %rax , unsigned(%r8)
incq %r8

movq par6 , %rax
movq %rax , unsigned(%r8)

我尝试打印元素来检查是否一切正常，只有最后一个打印正常，其他两个有一些奇怪的值。

也许这不是我应该声明和使用它的方式？

Answer 1

首先，unsigned 是 C 中类型的名称，因此对于数组来说它不是一个糟糕的选择。我们将其命名为 arr。

您希望将 BSS 中的该空间 block 视为数组 qword 元素。所以每个元素是8个字节。 因此您需要存储到 arr+0、arr+8 和 arr+16。(总计数组的大小为 10000 字节，即 10000/8 qwords)。

但是您使用 %r8 作为字节偏移量，而不是缩放索引。在其他条件相同的情况下，这通常是一件好事；在某些情况下，索引寻址模式在某些 CPU 上速度较慢。但问题是你只能使用 inc 将其增加 1，而不是使用 add $8, %r8。

所以您实际上是存储到 arr+0、arr+1 和 arr+2，其中 8-彼此重叠的字节存储，只留下最后一个存储的最低有效字节。 x86 是小端字节序，因此内存的结果内容实际上是这个，后面是其余未写入的字节，这些字节保持为零。

# static array that matches what you actually stored
arr: .byte 500 & 0xFF, 10, 15, 0, 0, 0, 0, 0, 0, 0, ...

您当然可以在 .data 部分中使用 .qword 来声明包含所需内容的静态数组。但由于只有前 3 个元素非零，因此将其放入 BSS 对于那么大的元素是有意义的，而不是将操作系统页面放入磁盘中的零中。

---

如果您要完全展开而不是在从 par4 开始的 3 元素 qword 数组上使用循环，则根本不需要增加寄存器。您也不需要将初始值设定项放在数据内存中，您可以只使用立即数，因为它们都适合 32 位符号扩展。

  # these are assemble-time constants, not associated with a section
.equ par4, 500
.equ par5, 10
.equ par6, 15

.text  # already the default section but whatever

.globl _start
_start:
    movq    $par4, arr(%rip)            # use RIP-relative addressing when there's no register
    movq    $par5, arr+8(%rip)
    movq    $par6, arr+16(%rip)

    mov $60, %eax
    syscall               # Linux exit(0)

.bss
    arr:   .skip 10000

您可以在 GDB 下运行它并检查内存以查看您得到的结果。 (使用gcc -nostdlib -static foo.s编译)。在 GDB 中，使用 starti 启动程序(在入口点停止)，然后使用 si 单步执行。使用 x/4g &arr 将 arr 处的内存内容转储为 4 个 qword 的数组。

或者，如果您确实想使用寄存器，也可以只循环指针而不是索引。

    lea     arr(%rip), %rdi           # or mov $arr, %edi in a non-PIE executable
    movq    $par4, (%rdi)
    add     $8, %rdi                  # advance the pointer 8 bytes = 1 element
    movq    $par5, (%rdi)
    add     $8, %rdi
    movq    $par6, (%rdi)

或缩放索引:

## Scaled-index addressing
    movq    $par4, arr(%rip)
    mov     $1, %eax
    movq    $par5, arr(,%rax,8)       # [arr + rax*8]
    inc     %eax
    movq    $par6, arr(,%rax,8)

---

有趣的技巧:您可以只使用字节存储而不是 qword 存储来设置低字节，并将其余部分保留为零。这会节省代码大小，但如果您立即执行 qword 加载，则会出现存储转发停顿。 (存储/重新加载将缓存中的数据与存储缓冲区中的存储合并的存储/重新加载有大约 10 个周期的额外延迟)

---

或者，如果您确实仍然想从.rodata中的par4复制24个字节，您可以使用上交所。 x86-64 保证 SSE2 可用。

    movaps   par4(%rip), %xmm0
    movaps   %xmm0, arr(%rip)          # copy par4 and par5

    mov      par6(%rip), %rax          # aka par4+16
    mov      %rax, arr+16(%rip)

.section .rodata          # read-only data.
.p2align 4         # align by 2^4 = 16 for movaps
  par4:  .quad 500
  par5:  .quad 10
  par6:  .quad 15

.bss
.p2align 4        # align by 16 for movaps
  arr: .skip 10000
# or use .lcomm arr, 10000  without even switching to .bss

或者使用 SSE4.1，您可以加载+扩展小常量，这样您就不需要为要复制到 BSS 数组中的每个小数字提供整个 qword。

    movzxwq    initializers(%rip), %xmm0       # zero-extend 2 words into 2 qwords
    movaps     %xmm0, arr(%rip)
    movzwl     initializers+4(%rip), %eax      # zero-extending word load
    mov        %rax, arr+16(%rip)

.section .rodata
  initializers: .word 500, 10, 15