c - MIPS:将 C 代码转换为 MIPS 函数调用和返回中的问题

Question

我需要将下面的 C 代码更改为 MIPS 代码，但我是 MIPS 新手，并坚持使用它。

这是 C 代码:

int main()
{
    int a, b, result;
    if(a == b)
         result = a*b;
    else
         result = assess(a, b);
    return result;
}

int assess(int a, int b)
{
    if(b<a)
        return upgrade(a, b);
    else
        return demote(a, b);
}

int upgrade(int a, int b)
{
    return 4*(a+b);
}

int demote(int a, int b)
{
    return 4*(b-a);
}

这是我编写的 MIPS 代码，它不起作用(我知道其中存在重大错误和错误)。由于我对语言不熟悉，我的主要问题是使用堆栈、返回和调用函数。

.data
    a:.word 8
    b:.word 8
    result:.word 0
main:
    li $s0 a
    li $s1 b
    li $s3 result
    beq $s0,$s1,Resultmul ELSE
    add $s3,$s3,assess

assess:
    blt $s1,$s0,upgrade
    bge $s1,$0,demote
Resultmul :
    mul $s3,$s1,$0

upgrade:
    addi $sp,$sp,-4
    sw $0,0($sp)
    add $t1,$a0,$a1
    mul $t1,$t1,4
    add $v0,$s0,$zero
    lw $s0,0($sp)
    addi $sp,$sp,4
    jr $ra
demote:
    addi $sp,$sp,-4
    sw $0,0($sp)
    sub $t1,$a0,$a1
    mul $t1,$t1,4
    add $v0,$s0,$zero
    lw $s0,0($sp)
    addi $sp,$sp,4
    jr $ra

如果有人可以提供帮助，那将是一个救星。

Answer 1

我不会为您提供完整的解决方案，因此您可以从练习中学习，但我建议您使用模板进行工作，例如此模板。

我使用了 Visual Studio Code(具有 MIPS 支持和更好的 MIPS 支持以突出显示)，其中每个空格或选项卡都使我可以通过这些空格折叠它，以及 QtSpim，我可以在其中运行它并得到输出64。

此外，我习惯使用制表符进行编码；这对我来说更清楚，但对您来说可能不太清楚，所以如果您必须删除所有选项卡和评论，我很抱歉。

######################## pseudo ####################################
 #
 #  int main()
 #  {
 #      int a, b, result;
 #      if(a == b)
 #           result = a*b;
 #      else
 #           result = assess(a, b);
 #      return result;
 #  }
 #  
 #  int assess(int a, int b)
 #  {
 #      if(b<a)
 #          return upgrade(a, b);
 #      else
 #          return demote(a, b);
 #  }
 #  
 #  int upgrade(int a, int b)
 #  {
 #      return 4*(a+b);
 #  }
 #  
 #  int demote(int a, int b)
 #  {
 #      return 4*(b-a);
 #  }
 #  
###################### DATA Segment ################################

    .data
 A:
    .word 8
 B:
    .word 8
 result:
    .word 0

###################### CODE Segment ################################

    .text
    .globl main
 main:

在这里你犯了一个小错误:你已经存储了这些单词，所以你还应该加载这些单词。否则，您必须输入 li $t0, 8。

    # int A = A, B = B, result
    lw      $s0, A      # $s0 = A
    lw      $s1, B      # $s1 = B
    lw      $s2, result # $s2 = result    
    # if (a == b)
        bne     $s0, $s1, noteq # if $s0 != $s1 then noteq
        # result = multiply(a,b);
        move    $a0, $s0        # $a0 = $s0
        move    $a1, $s1        # $a1 = $s1
        jal     multiply        # jump to multiply and save position to $ra
        sw      $v0, result     #         
        b       end             # branch to end
    # else
        noteq:
        # result = assess(a,b);
        move    $a0, $s0        # $a0 = $s0
        move    $a1, $s1        # $a1 = $s1
        # jal       assess      # jump to assess and save position to $ra
        sw      $v0, result     #         
        b       end             # branch to end (this rule can be left out)
    end:
    # printf("%i", result)
    li      $v0, 1      # $v0 = 1
    lw      $a0, result #     
    syscall
    # exit()
    li      $v0, 10     # $v0 = 10
    syscall

由于它们是伪代码中的函数，因此它们也应该被视为程序集中的函数。这意味着它们是用 j (对于像 exit 这样的非返回函数)或 jal (并用 jr 返回)来调用的。

我做了一个完全不必要的函数multiply来向您展示模板，这对于较大的函数来说非常方便。

###################### FUNC Segment ################################

###################### FUNCTION ####################################
 # multiply(A, B)
 #
 # Purpose: <General description>
######################## i/0 #######################################
 # Input:
  # $a0 = A
  # $a1 = B
 # Output: 
  # $v0 = value
 # Registers being used:
  # $s0 = A
  # $s1 = B
  # $s2 = value
######################## pseudo ####################################
 #  
 #  int multiply(int A, int B)
 #  {
 #      return A * B;
 #  }
 #
######################## <code> ####################################
 multiply:#(A, B)

始终存储要覆盖的寄存器的内容，以便您可以调用其他函数而不会丢失任何内容。还要立即初始化新寄存器中存储在 $a0-$a3 中的参数，因为在使用 syscall 打印内容时您可能会覆盖这些参数。

存储变量有两个主要原因:

1. 函数调用想要在不知不觉中更改您的 $s0-$s7 寄存器之一。
2. 可以在当前函数内调用其他函数，并使用它们自己的堆栈处理，因此再次无需担心寄存器。在创建评估函数之前了解一下可能会很有趣。

这是函数参数初始化的样子:

    # store(&return, parameters that are about overwritten)
    sub     $sp, $sp, 16    # $sp = $sp - 16
    sw      $ra, 0($sp)     #
    sw      $s0, 4($sp)     # 
    sw      $s1, 8($sp)     #
    sw      $s2, 12($sp)    # 
    # int A = A, B = B, value
    move    $s0, $a0        # $s0 = $a0
    move    $s1, $a1        # $s1 = $a1

这是非常短的函数体。正如您所知，存储所有这些参数是愚蠢的，因此不要创建这些开销函数。

    # value = A * B;
    mul     $s2, $s0, $s1

这是为了处理函数的返回。在较大的函数中，大多数时候您需要一个标签来跳转到返回处理。我总是在函数 foo 中调用标签，例如 foo_thisLabel，但这只是我的建议。

    move    $v0, $s2        # $v0 = $s2
    # restore()
    lw      $ra, 0($sp)     #   
    lw      $s0, 4($sp)     # 
    lw      $s1, 8($sp)     # 
    lw      $s2, 12($sp)    #     
    addi    $sp, $sp, 12    # $sp = $sp + 12
    # return index
    jr      $ra             # jump to $ra
######################## </code> ###################################

请注意，我只等待函数的返回段将值移至返回寄存器$v0。

这是其他函数的空模板。

###################### FUNCTION ####################################
 # <name of function>
 #
 # Purpose: <General description>
######################## i/0 #######################################
 # Input:
  # $a0 = 
  # $a1 = 
  # $a2 = 
  # $a3 = 
 # Output: 
  # $v0 = 
 # Registers being used:
  # $t0 = 
  # $t1 = 
  # $t2 = 
  # $s0 = 
  # $s1 = 
  # $s2 = 
  # $s3 = 
  # $s4 = 
######################## pseudo ####################################
 #  
 #  int assess(int a, int b)
 #  {
 #      if(b<a)
 #          return upgrade(a, b);
 #      else
 #          return demote(a, b);
 #  }
 #
######################## <code> ####################################
 #
######################## </code> ###################################

附注我已重命名您的变量名称，因为 b 可能会导致错误。