prolog - 具有一条规则的纯 Prolog 元解释器

Question

我想知道是否有一个纯粹的Prolog元解释器 只有一条规则。通常的 Prolog vanilla 元解释器有两个 规则。内容如下:

solve(true).
solve((A, B)) :- solve(A), solve(B). /* rule 1 */
solve(H) :- program(H, B), solve(B). /* rule 2 */

这个 Prolog vanilla 元解释器使用两个规则 /* 规则 1 */ 和 /* 规则 2 */。其余的都是事实。该程序 执行由程序事实表示。这是一个示例程序:

program(append([], X, X), true).
program(append([X|Y], Z, [X|T]), append(Y, Z, T)).
program(nrev([], []), true).
program(nrev([H|T], R), (nrev(T, S), append(S, [H], R))).

还有一个示例查询:

?- solve(nrev([1,2,3], X)).
X = [3, 2, 1] .

有没有办法将程序以不同的方式表示为事实，以及 然后编写一个不同的元解释器，它只使用事实 除了单个规则而不是两个规则？会的东西 适用于所有纯 Prolog 程序，而不仅仅是 nrev 示例？

Answer 1

这是一个想法，使用列表来保存其余的计算:

solve([]).
solve([X|Xs]) :- program(X, Ys, Xs), solve(Ys).

program(true, Xs, Xs).
program(append([],X,X), Xs, Xs).
program(append([X|Y], Z, [X|T]), [append(Y,Z,T)|Xs], Xs).
program(nrev([],[]), Xs, Xs).
program(nrev([H|T],R), [nrev(T,S),append(S,[H],R)|Xs], Xs).

通过测试调用(需要将调用包装在列表中)。

?- solve([nrev([1,2,3],X)]).
X = [3,2,1] ? ;
no

可以说，人们可以将program/3事实表示为DCG，以提高可读性(但随后它可能不再被视为“事实”)。