clojure - 一种收集 Clojure Let 表达式的所有绑定(bind)的方法

Question

我发现自己正在编写一个函数，该函数传递封闭的 let 表达式中绑定(bind)的每个变量。此场景的简化形式(伪代码)为

(let [a 1 b 2 c 3 d 4 e 5 f 6]
  (do-something a b c d)
  (f a b c d e f g)
  (compute-another-thing a c))

而我想写一些更像......的东西

(let env-name [a 1 b 2 c 3 d 4 e 5 f 6]
   (do-something (take 4 env-name))
   (f env-name)
   (compute-another-thing a c))

也就是说，clojure 核心(或外部可靠的东西)是否提供了一个 let 变体，将所有绑定(bind)收集到一个具有名称的集合中？

Answer 1

解构将使您达到目标:

(let [[a b c d e f :as env-name] [1 2 3 4 5 6]]
   (apply do-something (take 4 env-name))
   (apply f env-name)
   (compute-another-thing a c))

请注意，使用环境名称调用函数时必须使用apply。

对于更优雅的东西(例如您提议的形式)，我认为您必须编写自己的宏。

更新:这是一个(经过非常简单的测试)宏，可以处理简单的情况:

(defmacro let-as 
  [as-bind-name bindings & body]
  (let [lhs-bindings (map first (partition 2 bindings))]
    `(let ~bindings
       (let [~as-bind-name [~@lhs-bindings]]
             ~@body))))

只要正常的 let 绑定(bind)的左侧是简单符号(即不使用解构)，这应该可以满足您的要求。

一些 REPL 交互来说明:

core> (let-as env-name [a 1 b 2 c 3 d 4 e 5 f 6] (print env-name) (apply + env-name))
[1 2 3 4 5 6]
21

某些解构行为良好:

core> (let-as env-name [[a b] [1 2] [c d] [3 4]] (print env-name) (map first env-name))
[[1 2] [3 4]]
(1 3)

其他解构不是:

core> (let-as env-name [{:keys [a b]} {:a 1 :b 2}] (print env-name) (+ a b))
[{:keys [1 2]}]
3

这可以补救，但宏必须更复杂