lambda - 在定义宏的方法中处理 lambda 列表

Question

例如，我想从 lambda 列表中获取所有变量来定义宏:

(defmacro my-defun (name lambda-list &body body &aux (fname (gensym)))
  `(progn
     (defun ,fname ,(all-vars lambda-list)
       ,@body)
     (defun ,name ,lambda-list
       (,fname ,@(all-vars lambda-list)))))

是否有一些函数可以使用 lambda 列表来完成此操作或其他事情，或者是否没有比编写这样的函数更简单的方法:

(defun all-vars (lambda-list)
  (mapcar (lambda (cons) (if (consp cons) (car cons) cons))
          (remove-if (lambda (symbol) (and (symbolp symbol)
                                           (char= (char (symbol-name symbol) 0) #\&)))
                     lambda-list)))

Answer 1

这种方法是您必须做的事情，或者需要找到一个已经实现它的库。有一些库可以处理 lambda 列表解析(每个实现都必须这样做，至少在内部)。通常不会太难，只是乏味。

也就是说，您的 all-vars 实现不太正确。 ordinary lambda lists 中关键字参数的完整规范是:

[&key {var | ({var | (keyword-name var)} [init-form [supplied-p-parameter]])}* [&allow-other-keys]] 

这意味着您可以，例如，

(defun (&key ((:long-keyword-name x) "EX" xp))
  ...)

当你执行(if (consp cons) (car cons) cons)时，你会得到(:long-keyword-name x)，而不是<强>x。

这是一个我认为有效的版本，但尚未经过广泛测试:

(defun lambda-list-variables (lambda-list)
  "Returns, in order, the variables declared in an ordinary lambda list,
but doesn't check that the lambda-list is actually legal."
  (labels ((ll-keyword-p (x)
             (member x lambda-list-keywords))
           (to-var (x)
             (if (symbolp x)
                 x             ; required, optional, rest, key, and aux 
                 (destructuring-bind (var &rest init-and-supplied) x
                   (declare (ignore init-and-supplied))
                   (if (listp var)
                       (second var)     ; key vars
                       var)))))         ; optional, key, and aux vars
    (remove-if #'ll-keyword-p
               (mapcar #'to-var lambda-list))))

CL-USER> (lambda-list-variables
          '(a b 
            &optional c (d 'dee) (e 'ee e-p)
            &rest f
            &key
            g
            (h 'aitch)
            (i 'eye i-p)
            ((:jay j))
            ((:kay k) 'kay)            
            ((:ell l) 'ell l-p)
            &aux 
            m
            (n 'en)))
;=> (A B C D E F G H I J K L M N)