delphi - TDirect2DCanvas 中的字体方向不起作用？

Question

我需要在 TDirect2DCanvas 上绘制有角度的文本，但没有成功。

procedure TForm1.FormPaint(Sender: TObject);
var
  LCanvas: TDirect2DCanvas;
const
  myText = 'Kikimor';
begin
   LCanvas := TDirect2DCanvas.Create(Canvas, ClientRect);
   LCanvas.BeginDraw;
   try
     LCanvas.Font.Orientation := 90;
     LCanvas.TextOut(100,100,myText);
   finally
     LCanvas.EndDraw;
     LCanvas.Free;
   end;
end;

无论我给出什么方向的角度，它总是绘制直的文本。 定向不起作用还是我需要做其他事情？

Answer 1

设置 TDirect2DCanvas.Font.Orientation 没有任何效果(很可能没有实现，抱歉，没有时间调试)。 Delphi 中提供的 Direct2D 包装器非常基础。

为了实现您的目标，请手动应用转换:

procedure TForm1.FormPaint(Sender: TObject);
var
  LCanvas: TDirect2DCanvas;
  currentTransform: TD2D1Matrix3x2F;
  ptf: TD2DPoint2f;
const
  myText = 'Kikimor';
begin
  LCanvas := TDirect2DCanvas.Create(self.Canvas, ClientRect);
  LCanvas.BeginDraw;
  try
//    backup the current transformation
    LCanvas.RenderTarget.GetTransform(currentTransform);
    ptf.x:= 100.0; ptf.y:= 100.0;  //rotation center point
// apply transformation to rotate text at 90 degrees:
    LCanvas.RenderTarget.SetTransform(TD2D1Matrix3x2F.Rotation(90, ptf));
// draw the text (rotated)
    LCanvas.TextOut(100, 100, myText);
// restore the original transform
    LCanvas.RenderTarget.SetTransform(currentTransform);
  finally
    LCanvas.EndDraw;
    LCanvas.Free;
  end;
end;

有关更广泛的信息/效果，您可以查看: Drawing text using the IDWriteTextLayout.Draw() 整体Direct2D同一网站上的类别也很有趣(使用谷歌翻译)。