google-sheets - GSheets 论坛在领带分数上停滞不前

Question

背景信息

我正在尝试在 Google 表格上设置第一、第二和第三排名/评分系统。该工作表按行设置，每周添加一次新行。

1. 每行的左侧有六列。每列的顶部是一个单元格，其中包含该列的值标识符(例如人名或 ID#)。每周都会将分数输入到每一列中。

2.每行的右侧用于确定第一名、第二名和第三名获奖者。该区域还包含六列，标题为第一、第二、第三。我正在尝试进行设置，以便每周将新数字添加到下一行时，都会显示相关分数，并且旁边的单元格会显示与该周分数关联的名称/ID。然后重复第二次和第三次。

问题

一切都很完美； 除非平局。在这种情况下，信息会重复，因为它在第一个匹配时停止。我尝试过各种方法，包括使用“RANK()”和辅助列来消除重复的分数，但到目前为止，这让我感到困惑。怎么解决这个问题？

为了说明我想要做什么，我在这里有一个可编辑的示例表: https://docs.google.com/spreadsheets/d/1bmt77kQOtCu8OybNrWH48XKjBKD_HEZ_B6TqweZKEAI/edit?usp=sharing

Answer 1

在 J6 中使用:

=ARRAYFORMULA(ARRAY_CONSTRAIN(SORTN(SORT(SPLIT(
 FLATTEN(D6:I*1&"×"&D5:I5&"×"&ROW(D6:D)), "×"), 
 3, 1, 1, 0), 9^9, 2, 3, 1), COUNTA(B6:B), 2))

在 L6 中:

=ARRAYFORMULA(ARRAY_CONSTRAIN(SORTN(QUERY(QUERY(SORT(SPLIT(
 FLATTEN(D6:I*1&"×"&D5:I5&"×"&ROW(D6:D)), "×"), 3, 1, 1, 0), "offset 1", ), 
 "skipping "&COUNTA(D5:I5), ), 9^9, 2, 3, 1), COUNTA(B6:B), 2))

在 N6 中:

=ARRAYFORMULA(ARRAY_CONSTRAIN(SORTN(QUERY(QUERY(SORT(SPLIT(
 FLATTEN(D6:I*1&"×"&D5:I5&"×"&ROW(D6:D)), "×"), 3, 1, 1, 0), "offset 2", ), 
 "skipping "&COUNTA(D5:I5), ), 9^9, 2, 3, 1), COUNTA(B6:B), 2))