matrix - 基本高斯消除求解器产生错误结果

Question

我是 Fortran 新手，我需要编写高斯消元法代码来求解 4x4 矩阵。我的下面的代码返回错误的结果，并且我无法调试该问题。如果您能帮助我，我将不胜感激。

      common /grid/ A(100,100), NEQ, C(100), X(100)

      open(10, file="NEQ.txt", status='unknown')
      read(10,*) NEQ
      close (10)

      open(12, file="C1.txt", status='unknown')
        do i=1,NEQ
        read(12,*) C(i)
        enddo
      close (12)

      open(11, file="A1.txt", status='unknown')
        do i=1,NEQ
        read(11,*) (A(i,k), k=1,NEQ)
        enddo
      close (11)

      call SOL

      open(13, file="X.txt", status='unknown')
        do i=1,NEQ
        write(13,*) X(i)
        enddo
      close (13)

      stop
      end

      subroutine SOL
      common /grid/ A(100,100), NEQ, C(100), X(100)


c     Forward Reduction Phase:

      do 10 K=2,NEQ
      do 10 I=K,NEQ
      R=A(I,K-1)/A(K-1,K-1)

      C(I)=C(I)-R*C(K-1)

      do 10 J=K-1,NEQ
10    A(I,J)=A(I,J)-R*A(K-1,J)

c     Back Substitution Phase:

      X(NEQ)=C(NEQ)/A(NEQ,NEQ)
      do 30 K=NEQ-1,1,-1
      X(K)=C(K)
      do 20 J=K+1,NEQ

20    X(K)=X(K)-A(K,J)*X(J)
30    X(K)=X(K)/A(K,K)

      return
      end

---

对于我的情况，NEQ 从文本文件中读取为 4 我的 A1.txt 是:

18, -6, -6, 0
-6, 12, 0, -6
-6, 0, 12, -6
0, -6, -6, 18

C1.txt 是:

60
0
20
0

最终的 X 矩阵为:

8.3333330    
6.6666665    
8.3333321    
4.9999995    

而不是:

13.13
14.17
15.83
15.00

Answer 1

正如 Vladimir F 所评论的，如果您必须编写任何新代码，那么至少使用 Fortran 90 是非常有帮助的。它提供了比 Fortran 77 更好的选项来保持代码的结构化和组织性(和可读性)。我想补充一点，implicit none 也是减少错误的宝贵声明。

也就是说，下面是您的算法在 Fortran 90 中的示例(我已将其编写为函数):

function gaussian_elimination(A, C) result(X)
  implicit none
  real, intent(inout) :: C(:), A(size(C), size(C))
  real :: X(size(C))

  real    :: R(size(C))
  integer :: i, j, neq

  neq = size(C)

  ! Forward reduction, only two loops since reduction is now row by row
  do i = 1, neq
    R = A(:,i)/A(i,i)

    do j = i+1, neq
      A(j,:) = A(j,:) - R(j)*A(i,:)
      C(j) = C(j) - R(j)*C(i)
    enddo
  enddo

  ! Back substitution, only one loop
  do i = neq, 1, -1
    x(i) = (C(i) - sum(A(i, i+1:) * x(i+1:))) / A(i,i)
  enddo
end function gaussian_elimination

这只让我想知道为什么您认为您的结果X = [8.33, 6.67, 8.33, 5.00]不正确？这是正确的解决方案，您可以通过将矩阵 A 与其相乘来验证:matmul(A, X) 应(几乎)等于 C。