xslt - XQuery 链接 XSLT 转换

Question

我正在尝试通过 eXist 中的一系列 XSL 样式表转换来转换 XML 文档。我想将其从 pubs2 向上转换为 pubs9。 (我需要将一个转换的结果文档链接到下一个转换)我尝试了几种不同的方法，我认为它会是这样的:

let $trans1 := for $a in $stylesheet/version[@pub = '3'] return transform:transform(doc("/db/myXML.xml"), $a, ())

let $trans2 := for $b in $stylesheet/version[@pub = '4'] return transform:transform(doc($trans1), $b, ())

等等

let $trans9 := for $z in $stylesheet/version[@pub = '9'] return transform:transform(doc($trans8), $z, ())
return $trans9

但我不断收到基数错误。有其他方法吗？

顺便说一句:我正在使用 XQuery 1.0。我希望尽快转换到3.0。 :)

Answer 1

您可以使用递归将一系列 XSLT 应用于源文档，将第一个的输出链接到第二个的输入，依此类推。我在下面编写了函数 local:transform-pipeline，它是一个通用函数，展示了其工作原理。

xquery version "1.0";

import module namespace transform = "http://exist-db.org/xquery/transform";

declare function local:transform-pipeline($src as document-node()+, $transforms as xs:anyURI*, $params as node()?) as document-node()+ {
    if(empty($transforms))then
        $src
    else
        let $results := 
            for $s in $src
            return
                for $result in transform:transform($s, doc($transforms[1]), $params)
                return
                    document { $result }
        return            
            local:transform-pipeline($results, subsequence($transforms, 2), $params)
};


let $xslts := (xs:anyURI("/db/1.xslt"), xs:anyURI("/db/2.xslt"), xs:anyURI("/db/n.xslt"))
return
    local:transform-pipeline(doc("/db/my-document.xml"), $xslts, ())