arrays - 在 Julia 1.0 中对特征值/特征向量进行排序

Question

这个问题并不是需要解决方案，而是问我的方法对于 Julia 语言是否自然(Julianic？)，如果不是，什么是更自然的实现:

@doc """
function sorteigen!(evals::Array{Number,1},evecs::Array{Number,2})

Sort the eigenvalues and vectors.
"""
function sorteigen!(evals::Array{Number,1},evecs::Array{Number,2})
n=size(evecs)[1];

#Shallow copy and force local scope
local sortedevals = copy(evals);
local sortedevecs = copy(evecs);

#Sort eigenvalue Array{Number,1}
sortedindex = sortperm(evals);
evals[:] = sortedevals[sortedindex];

#Sort eigenvectors
for i=1:n
    sortedevecs[:,i] = evecs[:,sortedindex[i]];
end

evecs[:,:] = sortedevecs[:,:]

end

Answer 1

在这种情况下我会创建一个非变异函数:

function sorteigen(evals::Vector{T},evecs::Matrix{T}) where {T<:Real}
    p = sortperm(evals)
    evals[p], evecs[:, p]
end

如果您确实需要节省内存，那么您可以执行以下就地操作的操作:

function sorteigen!(evals::Vector{T},evecs::Matrix{T}) where {T<:Real}
    p = sortperm(evals)
    s = similar(evals)
    for i in axes(evecs, 1)
        for (j, pv) in enumerate(p)
            @inbounds s[pv] = evecs[i, j]
        end
        for j in eachindex(s)
            @inbounds evecs[i, j] = s[j]
        end
    end
    sort!(evals), evecs
end

它将提高内存效率，但可能会更慢，因为我们按行操作，因此无法应用 SIMD。

另请注意，我在方法的签名中使用 Real，因为一般 Number 不必定义顺序(特别是复数)。