azure - 如何将现有路由表添加到子网

Question

我是二头肌新手，我正在尝试将名为“udr-test”的现有 UDR 连接到 2 个子网，不幸的是没有运气。

这是我的模板，可以正常工作，但没有 UDR 配置:

var addressSpace = [
  '10.0.0.0/16'
]

var subnets = [
  {
    name: 'Subnet1'
    subnetPrefix: '10.0.2.0/24'
  }
  {
    name: 'Subnet2'
    subnetPrefix: '10.0.3.0/24'
  }
]

resource VNET 'Microsoft.Network/virtualNetworks@2021-02-01' existing  = {
  name: 'vnet-test'
}

@batchSize(1)
resource Subnets 'Microsoft.Network/virtualNetworks/subnets@2020-11-01' = [for (sn, index) in subnets: {
  name: sn.name
  parent: VNET
  properties: {
    addressPrefix: sn.subnetPrefix
  }
}]

您知道如何修改模板以添加 UDR 吗？

Answer 1

子网资源上有 routeTable 属性(请参阅 documentation ):

// reference to existing route table 
resource routeTable 'Microsoft.Network/routeTables@2022-01-01' existing  = {
  name: 'udr-test'
}

@batchSize(1)
resource Subnets 'Microsoft.Network/virtualNetworks/subnets@2020-11-01' = [for (sn, index) in subnets: {
  name: sn.name
  parent: VNET
  properties: {
    addressPrefix: sn.subnetPrefix
    routeTable:{
      id: routeTable.id // assign the route table
    }
  }
}]