azure - 嵌套资源不能出现在带有 for 表达式的资源内部

Question

我想生成一个带有二头肌和几个主题的 ESB。每个主题可以有一个或多个订阅。这些都在此列表中定义。

var topics = [{
  name: 'topic.one'
  subscriptions: [ 'esm', 'erp', 'pms' ]
}, {
  name: 'topic.two'
  subscriptions: [ 'esm' ]
}, {
  name: 'topic.three'
  subscriptions: [ 'erp', 'insights' ]
}, {
  name: 'topic.four'
  subscriptions: [ 'pms', 'cmdb']
}, {
  name: 'topic.five'
  subscriptions: [ 'billing', 'custom', 'erp', 'dax' ]
}]

当我创建资源时，最简单、最动态的解决方案将在循环内创建一个循环，如下所示。

resource sb_events 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' = {
  name: 'servicebus-events'
  location: 'westeurope'
  sku: {
    capacity: 1
    name: 'Standard'
    tier: 'Standard'
  }

  resource topic_resources 'topics' = [for topic in topics: {
    name: topic.name  

    resource subscription_resources 'subscriptions' = [for subscription in topic.subscriptions: {
      name: subscription
      properties: vSubscriptionProperties
    }]
  }]
}

但这给了我下一个错误:

A nested resource cannot appear inside of a resource with a for-expression. bicep(BCP160)

当这段代码看起来符合逻辑时，二头肌编译器不接受它。我该如何解决这个问题？

Answer 1

Bicep 目前不支持嵌套循环:

• https://github.com/Azure/bicep/discussions/1280

您可以有一个创建主题和订阅的模块:

// sb-topic-and-subscriptions.bicep
param namespaceName string
param topicName string
param subscriptionNames array
param vSubscriptionProperties  object

resource namespace 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' existing = {
  name: namespaceName
}

resource topic 'Microsoft.ServiceBus/namespaces/topics@2022-01-01-preview' = {
  parent: namespace
  name: topicName

  resource subscriptions 'subscriptions' = [for sub in subscriptionNames: {
    name: sub
    properties: vSubscriptionProperties
  }]
}

然后你可以从你的 main 中调用它:

...
// loop and create all the topics and subscription.
module topicsModule 'sb-topic-and-subscriptions.bicep' = [for topic in topics: {
  name: topic.name
  params: {
    namespaceName: 'servicebus-events'
    subscriptionNames: topic.subscriptions
    topicName:  topic.name
    vSubscriptionProperties: vSubscriptionProperties
  }
}]