f# - 如何在计算表达式中定义自定义运算符

Question

我想在我的计算表达式上定义一些自定义运算符，但无法使其工作

type ZipSeq() =

    [<CustomOperation("<*>")>]
    member this.Apply f s = 
        f |> Seq.zip s |> Seq.map (fun (y, x) -> x(y))

    member this.Return x = 
        Seq.initInfinite (fun _ -> x)

    // (a -> b) -> seq<a> -> seq<b>
    [<CustomOperation("<!>")>]
    member this.Map f s =
        this.Apply (this.Return f) s

let zipSeq = new ZipSeq()

let f (a : float) = a * a
let s = seq { yield 1. }

// seq<b>
let h1 = zipSeq.Map f s

//thinking h1 should be the same as h2
//but compilation error : ` This value is not a function and cannot be applied`
let h2 = zipSeq { return f <!> s }

顺便说一句，将 member this.Map f s ... 更改为 member this.Map (f, s) ... 会产生相同的错误。

Answer 1

正如评论中已经提到的，计算表达式和自定义运算符是两个正交的语言功能，不会以任何方式交互。如果您想使用自定义运算符，您可以定义自定义运算符并使用它(您可以将它们定义为类型的成员以限制其范围，或者定义为必须显式打开的模块的成员)。

如果您有兴趣将计算表达式用于应用程序编程风格之类的内容，那么值得注意的是，您可以在计算表达式中定义“类似 zip 的”操作。这使您可以使用良好的语法编写压缩:

zipSeq {
  for x in [1; 2; 3] do
  zip y in ['a'; 'b'; 'c'] 
  yield x, y }

这会产生一个带有 [1,a; 的序列2，b； 3，c]。 让您执行此操作的计算构建器定义如下所示:

type SeqZipBuilder() = 
    member x.For(ev:seq<'T>, loop:('T -> #seq<'U>)) : seq<'U> = 
      Seq.collect loop ev
    member x.Yield(v:'T) : seq<'T> = seq [v]
    [<CustomOperation("zip",IsLikeZip=true)>]
    member x.Zip
      ( outerSource:seq<'Outer>,  innerSource:seq<'Inner>,  
        resultSelector:('Outer -> 'Inner -> 'Result)) : seq<'Result> =
        Seq.map2 resultSelector outerSource innerSource

let zipSeq = SeqZipBuilder()

(据我所知，这并没有很好的记录，但是F# repo tests中有很多示例展示了如何定义类似zip(和其他)的自定义操作。)