c++ - 如何处理 C++ 的 objective-c 委托(delegate)？

Question

简短版本:我有一个 Qt/C++，我必须向其中添加有限数量的 Cocoa/Objective-C 代码。我已将 .cpp 文件更改为 .mm 文件，并将 objective-c 代码/对象添加到所述文件，它可以编译并运行。我现在需要我创建的其中一个对象的委托(delegate)——确切地说是一个 NSPopUpButton(或者更确切地说，它的菜单)——我被卡住了。如何为此对象添加委托(delegate)？

详细信息: 有问题的文件:

reportwindow.h, reportwindow.cpp 重命名为 reportwindow.mm - 这些文件包含我的原始 C++ 实现以及一些 objective-c 代码(打开包含 NSPopUpButton 的 NSSavePanel)。 reportwindow.h 额外包含在 .cpp 文件中，如果有区别的话。

menuHandler.h, menuHandler.mm - 这些文件包含一个(当前为空)objective-c 类，我打算将其用作委托(delegate)

我的第一个想法是我可以简单地让 C++ 类成为委托(delegate)，但这显然行不通，因为直接的 C++ 不理解委托(delegate)。然后我想我会创建一个单独的 objective-c 类作为 NSMenuDelegate 并将它的一个实例作为成员对象添加到我的 C++ 类中。因为我已经能够将其他 objective-c 对象添加为成员，所以我认为这应该可行。然而，一旦我在 C++ 类头文件中包含了我的新 objective-c 类的头文件，我就从苹果头文件(NSValue.h , NSObject.h, 等)所以显然这没有用，至少不是原样。在我的类头文件中包含任何 cocoa 头时，我得到相同的结果。

然后我想我会尝试对 objective-c 类进行前向声明(这就是我让其他 objective-c 对象工作的方式)。然而，这也不起作用——如果我将它声明为“class myClassName”，我会收到关于将类重新定义为不同类型符号的错误(大概是 c++ 类与 objective-c 协议(protocol))。如果我尝试将其转发声明为@protocol myClassName，我会收到有关“'@' 标记前的预期不合格 ID”的错误消息。那么我怎样才能让它发挥作用呢？

Answer 1

确定回答您的问题:

reportwindow.h is additionally included in a .cpp file, if that makes a difference.

它确实有所作为。任何涉及 Objective-C 代码的编译单元(在本例中为 cpp 文件)都必须重命名为 .mm 或 .m。在 C++ 文件中包含 Objective-C 内容的 header 将导致 C++ 编译器看到它无法处理的 Objective-C 代码的问题。

将 cpp 文件重命名为 mm 将在编译期间选择 Objective-C 选项(当文件命名为 cpp 或 c 时则不是)，因此允许使用 Objective-C 标记(主要是“@”你的情况)。

另一种方法是不将 Objective-C 委托(delegate)类包含到您的 C++ 类中，而是在 Objective-C 委托(delegate)中包含指向您的 C++ 类的指针(即以相反的方式实现)。通过这种方式，您可以安排一些事情，使 Objective-C 代码不接触 C++ 代码。

编辑:实际上，我更喜欢第二个建议。这是一个例子:

委托(delegate)类.h:

class MyCPPClassHandlingStuff;

@interface MyDelegateObject : NSObject <SomeDelegateProtocol> {
  MyCPPClassHandlingStuff *m_handlerInstance;
}

- (id) initWithCPPInstance:(MyCPPClassHandlingStuff*)cppInstance;

- (void) theDelegateProtocolMethod;

@end

委托(delegate)类.mm

#include "MyCPPClassHandlingStuff.h"

@implementation MyDelegateObject

- (id) initWithCPPInstance:(MyCPPClassHandlingStuff*)cppInstance
{
  self = [super init];
  if (self) {
    m_handlerInstance = cppInstance;
  }
  return self;
}

- (void) theDelegateProtocolMethod
{
  if (m_handlerInstance)
    m_handlerInstance->handleDelegateMethod();
}

@end

还有 MyCPPClassHandlingStuff.h:

#ifndef __MyCPPClassHandlingStuff_H__
#define __MyCPPClassHandlingStuff_H__

class MyCPPClassHandlingStuff
{
public:
  MyCPPClassHandlingStuff();
  void handleDelegateMethod();
};

#endif /* __MyCPPClassHandlingStuff_H__ */

MyCPPClassHandlingStuff 可以从 Objective-C 初始化，但您不能从那里的 C++ 代码初始化任何 Objective-C 类。如果您需要在 C++ 代码中使用 Objective-C，则必须将其编译为 Objective-C(即使用 .mm 文件)。我将 .cpp 的详细信息留给读者作为练习 ;)