为什么
我正在尝试从条形码扫描仪获取输入到我的(可视)应用程序。即使应用程序失去焦点，我也想忽略来自其他设备的输入并获取输入。我在 SO 和其他地方找到了推荐的 RawInput API 来实现这一点。
我专注于 GetRawInputBuffer()读取输入，因为我期望每秒扫描约 2 次，每次扫描触发约 700 个事件(按下/向上键)(假设扫描仪充当键盘)。该文档提到使用 GetRawInputBuffer() “用于可以产生大量原始输入的设备”。我不知道以上是否真的符合条件...
问题
我已经成功接收到输入数据 - 但我肯定做错了什么(可能根本上......)，因为我无法找到获得一致结果的好方法。原始数据似乎很快就会“消失”，而且我经常得不到任何数据。关于 GetRawInputBuffer() 在 SO 上存在类似的现有问题，但到目前为止它们只得到了我......一些注意事项:
- 我使用来自 https://github.com/lhengen/RawInput 的“unRawInput.pas”
- 我使用 AllocateHwnd() 创建一个窗口句柄并将其注册为原始输入
(编辑)问题
我应该如何/何时(正确地)在可视化应用程序中调用 GetRawInputBuffer() 以获得一致的结果，这意味着例如所有 自上次通话以来的关键事件？或者:事件如何/为什么在调用之间被“丢弃”，我该如何防止它？
代码
下面的代码是一个 64 位控制台应用程序，展示了我迄今为止尝试过的 3 种方法及其问题(如主要 begin-end.-block 的代码注释中所述的取消注释/注释掉方法)。
- 方法#1:在输入发生时休眠()，然后立即读取缓冲区。我从 the learn.microsoft.com sample code 想到 Sleep() - 它工作得很好，因为它似乎获得了所有输入，但我认为这不实用，因为我的应用程序需要保持响应。
- 方法 #2:使用 GetMessage() - 通常，这不会产生任何数据，除非您输入得非常快(例如，混合键)，即使如此，它也可能占输入的 50%，最高。
- 方法 #3:使用 PeekMessage() 和 PM_NOREMOVE - 这似乎非常一致地获得输入，但会最大化线程。
program readrawbuffer;
{$APPTYPE CONSOLE}
{$R *.res}
uses
WinAPI.Windows,
WinAPI.Messages,
System.Classes,
System.SysUtils,
URawInput in '..\URawInput.pas'; // from: https://github.com/lhengen/RawInput
type
TGetInput = class
strict private
fRawInputStructureSize: UINT;
fRawInputHeaderSize: UINT;
fRawInputBufferSize: Cardinal;
fRawInputDevice: RAWINPUTDEVICE;
fRawInputBuffer: PRAWINPUT;
procedure RawInputWndProc(var aMsg: TMessage);
public
fRawInputWindowHnd: HWND;
function ReadInputBuffer(): String;
constructor Create();
destructor Destroy(); override;
end;
constructor TGetInput.Create();
begin
inherited;
fRawInputStructureSize := SizeOf(RAWINPUT);
fRawInputHeaderSize := SizeOf(RAWINPUTHEADER);
// create buffer
fRawInputBufferSize := 40 * 16;
GetMem(fRawInputBuffer, fRawInputBufferSize);
// create handle and register for raw (keyboard) input
fRawInputWindowHnd := AllocateHWnd(RawInputWndProc);
fRawInputDevice.usUsagePage := $1;
fRawInputDevice.usUsage := $6;
fRawInputDevice.dwFlags := RIDEV_INPUTSINK;
fRawInputDevice.hwndTarget := fRawInputWindowHnd;
if RegisterRawInputDevices(@fRawInputDevice, 1, SizeOf(RAWINPUTDEVICE)) then
WriteLn('device(s) registered; start typing...')
else
WriteLn('error registering device(s): ' + GetLastError().ToString());
end;
destructor TGetInput.Destroy();
begin
if Assigned(fRawInputBuffer) then
FreeMem(fRawInputBuffer);
DeallocateHWnd(fRawInputWindowHnd);
inherited;
end;
function TGetInput.ReadInputBuffer(): String;
var
pcbSize, pcbSizeT: UINT;
numberOfStructs: UINT;
pRI: PRAWINPUT;
begin
Result := String.Empty;
pcbSize := 0;
pcbSizeT := 0;
numberOfStructs := GetRawInputBuffer(nil, pcbSize, fRawInputHeaderSize);
if (numberOfStructs = 0) then
begin
// learn.microsoft.com says for 'nil'-call: "minimum required buffer, in bytes, is returned in *pcbSize"
// though probably redundant, I guess it can't hurt to check:
if (fRawInputBufferSize < pcbSize) then
begin
fRawInputBufferSize := pcbSize * 16;
ReallocMem(fRawInputBuffer, fRawInputBufferSize);
end;
repeat
pcbSizeT := fRawInputBufferSize;
numberOfStructs := GetRawInputBuffer(fRawInputBuffer, pcbSizeT, fRawInputHeaderSize);
if ((numberOfStructs > 0) and (numberOfStructs < 900000)) then
begin
{$POINTERMATH ON}
pRI := fRawInputBuffer;
for var i := 0 to (numberOfStructs - 1) do
begin
if (pRI.keyboard.Flags = RI_KEY_MAKE) then
Result := Result + pRI.keyboard.VKey.ToHexString() + #32;
pRI := NEXTRAWINPUTBLOCK(pRI);
end;
{$POINTERMATH OFF}
// DefRawInputProc(); // doesn't do anything? http://blog.airesoft.co.uk/2014/04/defrawinputproc-rastinating-away/
end
else
Break;
until False;
end
end;
procedure TGetInput.RawInputWndProc(var aMsg: TMessage);
begin
// comment-out case block for Sleep() approach; leave last DefWindowProc() line
// leave case block for GetMessage() / PeekMessage() -approaches; comment-out last DefWindowProc() line
// case aMsg.Msg of
// WM_INPUT:
// begin
// Write(ReadInputBuffer(), '-');
// aMsg.Result := 0;
// end
// else
// aMsg.Result := DefWindowProc(fRawInputWindowHnd, aMsg.Msg, aMsg.WParam, aMsg.LParam);
// end;
// comment-out for GetMessage() / PeekMessage() -approaches
aMsg.Result := DefWindowProc(fRawInputWindowHnd, aMsg.Msg, aMsg.WParam, aMsg.LParam);
end;
var
getInput: TGetInput;
lpMsg: tagMSG;
begin
getInput := TGetInput.Create();
////////////////////////////////////////////////////////////////////////////////
// approach #1: Sleep()
// >> comment-out other aproaches; comment-out case block in RawInputWndProc(), leave last DefWindowProc() line
repeat
WriteLn('sleeping, type now...');
Sleep(3000);
WriteLn('VKeys read: ', getInput.ReadInputBuffer());
until False;
////////////////////////////////////////////////////////////////////////////////
// approach #2: GetMessage()
// >> comment-out other approaches; comment-out last DefWindowProc() line in RawInputWndProc(), leave case block
// repeat
// // learn.microsoft.com: "Use WM_INPUT here and in wMsgFilterMax to specify only the WM_INPUT messages."
// if GetMessage(lpMsg, getInput.fRawInputWindowHnd, WM_INPUT, WM_INPUT) then
// DispatchMessage(lpMsg);
// until False;
////////////////////////////////////////////////////////////////////////////////
// approach #3: PeekMessage()
// >> comment-out other approaches; comment-out last DefWindowProc() line in RawInputWndProc(), leave case block
// repeat
// if PeekMessage(lpMsg, getInput.fRawInputWindowHnd, WM_INPUT, WM_INPUT, PM_NOREMOVE) then
// DispatchMessage(lpMsg);
//
// if PeekMessage(lpMsg, 0, 0, 0, PM_REMOVE) then
// DispatchMessage(lpMsg);
// until False;
getInput.Free();
end.
最佳答案
我根据下面评论中的交流修改了这个“答案”并进行了测试。它不一定能回答我的问题，但代表了我目前的理解水平，并概述了我最终采用的方法(到目前为止似乎有效)
- 无论如何，RawInput 似乎都是通过 WM_INPUT 窗口消息发送的；是否使用
GetRawInputData()或GetRawInputBuffer() - 这意味着需要某种可以将消息发送到的窗口。这可以是一个隐藏的窗口。使用
CreateWindowEx(0, PChar('Message'), nil, 0, 0, 0, 0, 0, HWND_MESSAGE, 0, 0, nil);目前对我来说效果很好 - 这也意味着需要某种消息循环，以便处理消息(并且不会堆积)。
- 与
GetRawInputData()的区别似乎是 Windows 将“排队”WM_INPUT 消息，而GetRawInputBuffer()获取和删除(从队列中)一次发送多条消息。而且我认为唯一的优势是与必须“单独处理每个 WM_INPUT 消息”相比，这种方式可以更快地“接收”输入(更高的吞吐量)。 - 棘手的是
GetRawInputBuffer()似乎可以正常工作，最重要的是消息 except WM_INPUT 通过常规方式处理 - 然后是GetRawInputBuffer( )被定期调用，它处理排队的 WM_INPUT 消息。我采取的任何以某种方式“查看”WM_INPUT 消息的方法最终都会导致我从GetRawInputBuffer() 得到不一致/不完整的结果
下面是我的消息循环，主要是受 this SO answer 启发并在单独的线程中运行
repeat
TThread.Sleep(10);
while True do
begin
if (Not PeekMessage(lpMsg, 0, 0, WM_INPUT - 1, PM_NOYIELD or PM_REMOVE)) then System.Break;
DefWindowProc(lpMsg.hwnd, lpMsg.message, lpMsg.wParam, lpMsg.lParam);
end;
while True do
begin
if (Not PeekMessage(lpMsg, 0, WM_INPUT + 1, High(Cardinal), PM_NOYIELD or PM_REMOVE)) then System.Break;
DefWindowProc(lpMsg.hwnd, lpMsg.message, lpMsg.wParam, lpMsg.lParam);
end;
ReadRawInputBuffer(); // shown below; essentially reads out all queued-up input
until SomeCondition;
读取缓冲区(主要受 learn.microsoft.com 上的示例代码启发):
procedure ReadInputBuffer();
var
// ...
begin
// this returns the minimum required buffer size in ```pcbSize```
numberOfStructs := GetRawInputBuffer(nil, pcbSize, rawInputHeaderSize);
if (numberOfStructs = 0) then
begin
// read out all queued-up data
repeat
// ... allocate pBuffer as needed
numberOfStructs := GetRawInputBuffer(pBuffer, pcbSize, rawInputHeaderSize);
if ((numberOfStructs > 0) and (numberOfStructs < 900000)) then
// do something with pBuffer / its data
// I use a TThreadedQueue<T>; the items/data is worked off outside this thread
else
System.Break;
until False;
end
end;
(在超过 10 分钟的测试中，阅读 > 700'000 个关键事件似乎并没有让我失去一个(如果我的数字没有说谎的话)。使用 TStopWatch 和在消息循环开始时开始/停止(在 TThread.Sleep(10) 之后)并在耗尽输入队列后在结束时停止，在一次测试中在 15 秒内读取大约 12k 个事件(这是接近每秒 800 个事件)，最慢的运行测量... 0 毫秒。)
关于delphi - 原始输入 WinAPI : GetRawInputBuffer() and message handling，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/59809804/