winapi - 如何在 MASM 中为一个项目编写和组合多个源文件？

Question

对汇编还很陌生，玩得很开心。我想将我的程序的功能拆分到多个文件中，特别是通过将相似的功能组合在一起进行组织。这些其他文件将由主文件调用(希望甚至是其他非主文件)。我还没有设法做到这一点，希望得到帮助。

我没有使用 IDE，我更喜欢使用 notepad++、ml.exe 和 link.exe(来自 MASM 文件夹)自己编写、汇编和链接程序。我看过的大多数在线资源都假定使用 Visual Studio，并提供对我不起作用的代码，或者可能不完整 b/c IDE 做了其他事情。我不打算开始使用 IDE。

我想学习“最佳”方式，即对 future 项目最有用的方式。我是否可以将其设置为仅复制文件并编写几行代码以便将来在不同的项目中使用它？或者这可能是不好的做法，我应该学习一种更标准的方法来代替？我知道这个平台不适合自以为是的问题，我希望这个问题比观点更基于事实。

所有我能想到的有用信息:
语言:Masm 汇编 x86
计算机:64 位 Windows

代码:

运行.bat

@echo off

ml /c /coff /Zi /Fl Driver.asm
ml /c /coff /Zi /Fl Utils.asm

link /debug /subsystem:console /entry:start /out:Driver.exe Utils.obj Driver.obj \masm32\lib\kernel32.lib

Driver.exe

pause

驱动.asm

.386
.model flat
.stack 100h

ExitProcess PROTO Near32 STDCALL, dwExitCode:DWORD
ClearRegs PROTO

.DATA
.CODE

PUBLIC _start
_start:

    Main PROC
        MOV EAX, 0
        INVOKE ClearRegs
        INVOKE ExitProcess, 0
    Main ENDP

END

实用工具.asm

.386
.model flat
.stack 100h

OPTION PROC:PRIVATE ; Set procedures to private by default

PUBLIC ClearRegs

.DATA
.CODE
    
    ClearRegs PROC C
        XOR EAX, EAX
        XOR EBX, EBX
        XOR ECX, ECX
        XOR EDX, EDX
        XOR ESI, ESI
        XOR EDI, EDI
        RET
    ClearRegs ENDP

END

终端输出

Microsoft (R) Macro Assembler Version 6.14.8444
Copyright (C) Microsoft Corp 1981-1997.  All rights reserved.

 Assembling: Driver.asm
Microsoft (R) Macro Assembler Version 6.14.8444
Copyright (C) Microsoft Corp 1981-1997.  All rights reserved.

 Assembling: Utils.asm
Microsoft (R) Incremental Linker Version 5.12.8078
Copyright (C) Microsoft Corp 1992-1998. All rights reserved.

Driver.obj : error LNK2001: unresolved external symbol ClearRegs
Driver.exe : fatal error LNK1120: 1 unresolved externals
'Driver.exe' is not recognized as an internal or external command,
operable program or batch file.
Press any key to continue . . .

Answer 1

现在您的问题已经更新为最小的、完整的、可验证的示例，可以确定一些具体问题。当您使用 PROC 声明一个函数时每个函数都有一种语言命名和调用约定。不指定一个关联没有特殊处理。

您可以使用模型指令指定默认语言作为第二个参数。在您使用的两个文件中:

.model flat

所以您还没有关联默认语言。您已定义 ClearRegs作为:

ClearRegs PROC C
[snip]
ClearRegs ENDP

这里的问题是 PROC C指定C 语言调用约定和命名约定。对于 COFF 格式(32 位)，C 命名约定要求在函数名称的开头添加下划线 ( _ )。如果您要生成 MAP 文件，您会发现从 utils.asm 导出的函数名称实际上是 _ClearRegs而不是 ClearRegs .

有很多方法可以解决这个问题。您可以选择不将默认语言添加到 .model指令并告诉Driver.asm那ClearRegs通过更改定义为 C 原型(prototype):

ClearRegs PROTO

到

ClearRegs PROTO C

所以现在 utils.asm 正在导出 _ClearRegs Driver.asm 正在导入 _ClearRegs因为双方匹配并且 MASM 将处理添加额外的下划线。 INVOKE ClearRegs将使用与 PROTO 关联的命名约定声明语言是 C 所以它会添加额外的 _给你。

这带来了您可以进行的额外更改。一个END指令可用于指定程序的入口点，而不是使用 /entry:<name>在链接器命令行上。入口点的名称必须以 _ 开头以满足链接器。

您当前在 Driver.asm 中使用它:

PUBLIC _start
_start:

Main PROC
    [snip]
Main ENDP

END

而你使用 /entry:start链接时。您可以将其更改为:

_Main PROC
    [snip]
_Main ENDP

END _Main   ; END with a function name tells linker to use _Main as program entry point

链接时，您现在可以删除 /entry完全选项，您不需要 _start标签了。不过我们可以做得更好。 MS C 运行时启动调用的入口点假定该函数遵循 C 语言命名和调用约定。最好是这样做:

Main PROC C
    [snip]
Main ENDP

END Main   ; END with a function name tells linker to use _Main as program entry point

如果您打算实现所有功能 PROC C那么你可以避免指定 C在大多数地方，通过更改 Utils.asm 和 Driver.asm 中的默认语言来更改:

.model flat

到:

.model flat, C

这将更改 PROTO 的默认值声明，PUBLIC指定用 PROC 定义的函数的语句和 PROC陈述自己。 Driver.asm 中的代码可能如下所示:

.386
.model flat, C
.stack 100h

ExitProcess PROTO Near32 STDCALL, dwExitCode:DWORD
ClearRegs PROTO

.DATA
.CODE

Main PROC
    MOV EAX, 0
    INVOKE ClearRegs
    INVOKE ExitProcess, 0
Main ENDP

END Main

Utils.asm 看起来像:

.386
.model flat, C
.stack 100h

OPTION PROC:PRIVATE ; Set procedures to private by default

PUBLIC ClearRegs

.DATA
.CODE
    
ClearRegs PROC
    XOR EAX, EAX
    XOR EBX, EBX
    XOR ECX, ECX
    XOR EDX, EDX
    XOR ESI, ESI
    XOR EDI, EDI
    RET
ClearRegs ENDP

END

你会链接到:

link /debug /subsystem:console /out:Driver.exe Utils.obj Driver.obj \masm32\lib\kernel32.lib