aws-lambda - terraform:local_file 与 null_resource 的依赖性导致:没有这样的文件或目录

Question

我有一个 null_resource 执行一个创建 lambda zip 文件的 docker 命令(这是唯一的方法，因为我需要一些通常可以通过 apt-get 或 yum install 获得的编译库) - 因此不使用其他 terraform 提供的模块来创建 lambda 文件:

resource "null_resource" "install_dependencies" {
  provisioner "local-exec" {
    command = "docker run -w ${path.cwd}/lambda_folder/ foot.bar.docker >> ${path.cwd}/lambda_folder/lambda.zip"
  }
}

为了使用 aws_lambda_function 资源上传 lambda 文件，我需要使用 local_file 数据源:

data "local_file" "lambda_file" {
  filename = "${path.module}/lambda_folder/lambda.zip"
  depends_on = [
    null_resource.install_dependencies
  ]
}

上传 lambda 资源:

resource "aws_lambda_function" "database_rotation" {
  vpc_config {
    subnet_ids         = data.aws_subnet_ids.subnet_ids.ids
    security_group_ids = [data.aws_security_group.rotation_sg.id]
  }
  filename         = data.local_file.lambda_file.content
  function_name    = "foo_bar_lambda"
  role             = aws_iam_role.iam_for_lambda.arn
  handler          = "lambda_function.lambda_handler"
  runtime          = "python3.8"
  timeout          = 120
  environment { variables = var.env_vars }

  depends_on = [null_resource.install_dependencies]
}

这在第一次运行时一切正常 - 在我有 null_resource 和 data.local_file.lambda_file 的任何状态之前 - 但是一旦我的初始部署成功，terraform 将失败并出现以下错误:

Error: open ./lambda_folder/lambda.zip: no such file or directory

  on main.tf line 62, in data "local_file" "lambda_file":
  62: data "local_file" "lambda_file" {

这是有道理的 - null_resource 没有运行也没有创建 lambda.zip 文件。 我的问题是，如何解决这个问题？如何确保 data.local_file.lambda_file 不会每次都被触发，或者 null_resource 是否在我每次运行 terraform 时执行，从而创建/上传相同的 lambda.zip文件 我有点迷路，我会很感激任何帮助。谢谢!

Answer 1

不幸的是，这是一个困难的过程。您可以为 null_resource 使用 triggers 输入, 结合 fileexists函数和 uuid函数，像这样:

resource "null_resource" "install_dependencies" {
  triggers = {
    filefound = fileexists("${path.cwd}/lambda_folder/lambda.zip") ? "1" : uuid()
  }
  provisioner "local-exec" {
    command = "docker run -w ${path.cwd}/lambda_folder/ foot.bar.docker >> ${path.cwd}/lambda_folder/lambda.zip"
  }
}

这保证了它会在文件丢失时重新运行，但问题是它每次都会运行两次(一次当它发现文件丢失时，第二次当触发创建文件后 UUID 更改为“1”。但是，后续运行不应重新创建资源。

编辑: 真的很困扰我，没有办法做到这一点，所以I built a module解决了这个问题。在你的情况下，你会像这样使用它:

module "conditional_trigger" {
  source = "Invicton-Labs/conditional-trigger/null"
  // A new output ID will only be generated when this field is `true`
  regenerate = fileexists("${path.cwd}/lambda_folder/lambda.zip")
}

resource "null_resource" "install_dependencies" {
  triggers = {
    id = module.conditional_trigger.uuid
  }
  provisioner "local-exec" {
    command = "docker run -w ${path.cwd}/lambda_folder/ foot.bar.docker >> ${path.cwd}/lambda_folder/lambda.zip"
  }
}

这是一些严肃的黑魔法，但它适用于大多数情况。