f# - 使用 FSharpPlus 的 Reader monad 转换器示例

Question

我正在尝试理解 reader monad 转换器。我正在使用 FSharpPlus并尝试编译以下示例，它首先从阅读器环境中读取一些内容，然后执行一些异步计算，最后合并两个结果:

open FSharpPlus
open FSharpPlus.Data

let sampleReader = monad {
    let! value = ask
    return value * 2
}

let sampleWorkflow = monad {
    do! Async.Sleep 5000
    return 4
}

let doWork = monad {
    let! envValue = sampleReader
    let! workValue = liftAsync sampleWorkflow
    return envValue + workValue
}

ReaderT.run doWork 3 |> Async.RunSynchronously |> printfn "Result: %d"

有了这个，我在它说 let! value = ask 以及以下完全无用的(至少对我而言)错误消息:

Type constraint mismatch when applying the default type 'obj' for a type inference variable. No overloads match for method 'op_GreaterGreaterEquals'.

Known return type: Async

Known type parameters: < obj , (int -> Async) >

感觉好像我只是在某处缺少一些运算符，但我无法弄清楚。

Answer 1

您的代码是正确的，但在这种情况下 F# 类型推断并不那么聪明。

如果您向 sampleReader 添加类型注释，它将编译正常:

let sampleReader : ReaderT<int,Async<_>> = monad {
    let! value = ask
    return value * 2
}

// val sampleReader : FSharpPlus.Data.ReaderT<int,Async<int>> =
//  ReaderT <fun:sampleReader@7>

更新:

阅读您的评论后。 如果您想要使其通用，首先必须声明您的函数 inline否则无法应用类型约束:

let inline sampleReader = monad ...

但这会将您带到第二个问题:常量不能声明为内联(实际上有一种方法，但它太复杂了)只有函数可以。

所以最简单的就是让它成为一个函数:

let inline sampleReader () = monad ...

现在代码无法编译的第三个问题:)

再次在这里，您可以给类型推断一个最小的提示，只是在调用站点说您期望 ReaderT<_,_>就足够了:

let inline sampleReader () = monad {
    let! value = ask
    return value * 2
}

let sampleWorkflow = monad {
    do! Async.Sleep 5000
    return 4
}

let doWork = monad {
    let! envValue = sampleReader () : ReaderT<_,_>
    let! workValue = liftAsync sampleWorkflow
    return envValue + workValue
}

ReaderT.run doWork 3 |> Async.RunSynchronously |> printfn "Result: %d"

结论:

在 F# 中定义泛型函数并不是一项微不足道的任务。 如果您查看 F#+ 的源代码，您就会明白我的意思。

运行您的示例后，您会看到生成的所有约束，并且您可能会注意到如何通过使函数内联和通用来增加编译时间。

这些都表明我们正在将 F# 类型系统推向极限。

尽管 F#+ 定义了一些现成的泛型函数，并且有时可以通过组合这些函数来创建您自己的泛型函数，但这不是该库的目标，我的意思是您可以，但是你是一个人，在某些情况下，例如探索性开发，这可能是有意义的。