amazon-web-services - Terraform - 循环遍历对象列表的动态 block

Question

我正在尝试配置此 Terraform，以便添加新 SG 入口规则所需要做的就是向 .tfvars 文件添加一个 block ，新入口规则将被添加到单个 SG。

我有一个如下所示的 .tfvars 文件:

rules = [
  {
    protocol = "tcp"
    port = 22
    cidr = ["10.0.0.0/8"],
  },
  {
    protocol = "tcp"
    port = 80
    cidr = ["10.0.0.0/8"]
  },
  {
    protocol = "tcp"
    port = 443
    cidr = ["10.0.0.0/8"]
  },
  {
    protocol = "icmp"
    port = -1
    cidr = ["10.0.0.0/8"]
  }
]

我的 Terraform 是:

variable "rules" {
  type = list(object({
    protocol = string
    port = number
    cidr = list(string)
  }))
  description = "Specify the protocol, port range, and CIDRs."
}


resource "aws_security_group" "this" {
...

dynamic "ingress" {
  for_each = { for rule in var.rules : rule.id => rule }

  content {
    from_port   = var.rules.port
    to_port     = var.rules.port
    protocol    = var.rules.protocol
    cidr_blocks = var.rules.cidr
  }
}

...

我已经尝试遍历上面的内容，也尝试使用 for_each = var.rules 但我只收到以下错误(以下每个错误都会发生):

protocol     = var.rules.protocol
from_port    = var.rules.port
to_port      = var.rules.port
cidr_blocks  = var.rules.cidr
-----------------------------
var.rules is list of object with 4 elements. 
This value does not have any attributes.`

我有点卡住了，不知道还能尝试什么，所以有人有什么想法吗？

Answer 1

这里有几个问题。第一个是在您的 for_each 元参数值 for 表达式 lambda 中，您正试图访问 id 的不存在的对象键。此外，您可以轻松地在此处使用 list(object) 而不是像您在转换中尝试使用的 map(object) ，然后您的输入变量可以可以直接使用。我们可以丢弃那些并相应地修复值:

for_each = var.rules

第二个问题是动态 block 中的临时 lambda 迭代器变量是 block 本身的名称。在这种情况下，您的 block 被命名为 ingress。因此，我们需要从它的对象键访问值:

content {
  from_port   = ingress.value.port
  to_port     = ingress.value.port
  protocol    = ingress.value.protocol
  cidr_blocks = ingress.value.cidr
}

结合这些修复，我们得出:

dynamic "ingress" {
  for_each = var.rules

  content {
    from_port   = ingress.value.port
    to_port     = ingress.value.port
    protocol    = ingress.value.protocol
    cidr_blocks = ingress.value.cidr
  }
}