garbage-collection - 哈希表疑似SBCL垃圾回收Bug

Question

我在 Ubuntu 18.04 上使用 SBCL 1.4.5。

似乎 SBCL 中的垃圾收集器没有正确释放绑定(bind)到具有符号键和值的哈希表的内存。有趣的是，当键和值是整数时，垃圾回收工作正常。

例如，下面的程序可以正常运行:

(defun copy-hash-table (hash)
  (let ((h (make-hash-table
            :test (hash-table-test hash)
            :rehash-size (hash-table-rehash-size hash)
            :rehash-threshold (hash-table-rehash-threshold hash)
            :size (hash-table-size hash))))
    (loop for key being the hash-keys of hash
            using (hash-value value)
          do
             (setf (gethash key h) value)
          finally (return h))))

(defun make-integer-input ()
  (loop
    with hash1 = (make-hash-table) and hash2 =  (make-hash-table)
    for i from 0 to 500
    do
       (setf (gethash (random 100) hash1) (random 100))
       (setf (gethash (random 100) hash2) (random 100))
    finally
       (return (list hash1 hash2))))

(defun do-integer-work (hash1 hash2)
  (loop
    for i being the hash-keys of hash1
    for j being the hash-keys of hash2
    do
       (remhash i hash1)
       (setf (gethash i hash1) (random 100))
       (remhash j hash2)
       (setf (gethash j hash2) (random 100)))
  (values hash1 hash2))

(defun hash-worker (list-obj)
  (loop
    with next
    for i from 1 to 50000
    do
      (multiple-value-bind (new-hash1 new-hash2)
          (do-integer-work (copy-hash-table (first list-obj)) (copy-hash-table (second list-obj)))
        (setq next (list new-hash1 new-hash2))
        (if (> (random 100) 50)
            (setq list-obj next)))))

我通过调用 (hash-worker (make-integer-input)) 来运行这个程序。顶级函数 hash-worker 接收两个哈希表的列表，并在 do-integer-work 中处理哈希表的副本。然后，辅助函数输出两个修改后的哈希表，分别保存在new-hash1和new-hash2中。然后系统随机决定是否保留修改后的哈希表。

do-integer-work 辅助函数按顺序删除哈希表的键并使用新的随机值重新提交它们。

当这个程序运行时，我观察到内存消耗在程序运行期间基本保持不变。当我在具有符号键和值的哈希表上运行姊妹程序时，情况并非如此。

(defun copy-hash-table (hash)
  (let ((h (make-hash-table
            :test (hash-table-test hash)
            :rehash-size (hash-table-rehash-size hash)
            :rehash-threshold (hash-table-rehash-threshold hash)
            :size (hash-table-size hash))))
    (loop for key being the hash-keys of hash
            using (hash-value value)
          do
             (setf (gethash key h) value)
          finally (return h))))

(defun make-symbol-input ()
  (loop
    with hash1 = (make-hash-table) and hash2 =  (make-hash-table)
    for i from 0 to 500
    do
       (setf (gethash (gentemp) hash1) (gentemp))
       (setf (gethash (gentemp) hash2) (gentemp))
    finally
    (return (list hash1 hash2))))

(defun do-symbol-work (hash1 hash2)
  (loop
    for i being the hash-keys of hash1
    for j being the hash-keys of hash2
    do
       (remhash i hash1)
       (setf (gethash i hash1) (gentemp))
       (remhash j hash2)
       (setf (gethash j hash2) (gentemp)))
  (values hash1 hash2))

(defun hash-worker (list-obj)
  (loop
    with next
    for i from 1 to 50000
    do
      (multiple-value-bind (new-hash1 new-hash2)
          (do-symbol-work (copy-hash-table (first list-obj)) (copy-hash-table (second list-obj)))
        (setq next (list new-hash1 new-hash2))
        (if (> (random 100) 50)
            (setq list-obj next)))))

我运行这个程序时调用了 (hash-worker (make-symbol-input))。这个程序的不同之处在于顶层函数调用do-symbol-work。随着这个程序的运行，我观察到系统的内存使用量稳步增加，直到我的机器内存耗尽。

这是 SBCL 中的已知错误吗？如果是，是否有解决方法？

Answer 1

您正在使用 gentemp，它会保留它创建的符号。这样的符号不能被 GCd 因为它们被它们的包引用了。所以你正在生成大量的内部符号并杀死系统。相反，请使用 gensym。像这样的代码中可能仍然存在 GC 错误，但这不是一个。