excel - 比较两个字符串时类型不匹配

Question

我有以下代码将用户窗体(GUI)上的组合框与工作簿 sheet2 上的填充单元格进行比较，我收到“类型不匹配”错误。这一切都在起作用，直到另一个子将一些数据转移到表 2 上正在比较的单元格中。

我的问题在于 if Worksheets(sheet2).cells(1,i).value = LCase(GUI.superCB.Value) thenWorksheets(sheet2).cells(1,i).value现在在 watch 中显示为 Variant/Integer，这让我认为当数据移动时，它改变了该单元格的“样式”。

Private Sub NextButton_Click() ''' adds check boxes to frame

Dim i As Integer
'Dim superColm As Integer
For i = 5 To 12
    If Worksheets(Sheet2).Cells(1, i).Value = LCase(GUI.superCB.Value) Then 'problem line is right here
        superColm = i
        Exit For
    Else
    End If
Next i

NextButton.Visible = False
superCB.Visible = False

Run.Visible = True
Frame1.Visible = True



    Dim chk As Control
    Dim idx As Integer

    Dim lastrow As Integer
    lastrow = Worksheets(Sheet2).Cells(Rows.Count, superColm).End(xlUp).Row

    For idx = 1 To lastrow - 1
        Set chk = GUI.Frame1.Controls.add("Forms.CheckBox.1", idx, True)
        'set chk = gui.Frame1.Controls.Add(
        chk.Visible = True
        chk.Left = 5
        chk.Top = (idx - 1) * (chk.Height + 2)
        chk.Caption = Cells(idx + 1, superColm) & "   " & idx
    Next
    With Me.Frame1
        .ScrollBars = fmScrollBarsVertical
            If lastrow <= 10 Then
                .ScrollHeight = .InsideHeight * 1.5
            ElseIf lastrow <= 15 Then
                .ScrollHeight = .InsideHeight * 2.25
            ElseIf lastrow <= 20 Then
                .ScrollHeight = .InsideHeight * 3
            ElseIf lastrow <= 25 Then
                .ScrollHeight = .InsideHeight * 3.9
            ElseIf lastrow <= 30 Then
                .ScrollHeight = .InsideHeight * 4.75
            ElseIf lastrow <= 35 Then
                .ScrollHeight = .InsideHeight * 5.35
            Else
                .ScrollHeight = .InsideHeight * 6.25
            End If
        .ScrollWidth = .InsideWidth * 9
    End With
End Sub

如果我将工作表 2 作为事件工作表 Cells(1,i).value但是会起作用，我最终需要向用户隐藏工作表 2。通过这项工作，我认为单元格样式不是问题。

我试过去Excel.Workbooks("Shawn_sch_v1.2.xlsm").worksheets(sheet2).cells(1,i).value以及基本单元格()的所有内容，希望它缺少工作表引用，但没有任何帮助。

Answer 1

一个 String可以安全地与 VBA 中的任何其他数据类型进行比较...除了 Error .

比较 Variant/Error反对任何事情都会引发类型不匹配错误。

此代码隐式访问任何 ActiveSheet是:

chk.Caption = Cells(idx + 1, superColm) & "   " & idx

Cells应该使用特定的 Worksheet 来限定您打算使用的对象。如果事件工作表包含无法强制转换为 String 的值(例如 #VALUE! 或 #REF! )，这将引发类型不匹配错误。

Worksheets(Sheet2).Cells(1, i).Value = ...

这里Sheet2是一个标识符。 Worksheets indexer 需要一个整数值或一个字符串。如果 Sheet2是 ThisWorkbook 中工作表的代号，您不需要从 Worksheets 取消引用它- 只需使用它:

Sheet2.Cells(1, i).Value = ...

Worksheet类没有默认属性，所以 Debug.Print Worksheets(Sheet2)抛出错误 438 对象不支持此属性或方法 - 以及后续成员调用，如 .Cells(1, i) , 也会引发类型不匹配错误。如果您没有 Sheet2保存工作表名称的字符串变量，我怀疑这是您现在遇到的错误...这意味着上面的所有内容都在等着咬您:)

如果 Sheet2是一个包含有效工作表名称的字符串变量，您可以使用 IsError验证 Variant 是否存在的函数是 Variant/Error :

If Not IsError(Sheet2.Cells(1, i).Value) Then
    ' value is safe to compare against a string
Else
    ' comparing the cell value to anything will throw error 13
End If

最后，我建议不要使用 Rows作为一个全局变量，因为它已经是一个全局范围的标识符( [_Global].Rows ，隐式引用 ActiveSheet )。现在，如果不破坏您的代码，使用 Find/Replace 重命名该变量将非常困难:Rubberduck的“重命名”重构可能有助于安全地做到这一点(免责声明:我管理那个 OSS VBIDE 插件项目)。