excel - 为什么这段代码会导致无限循环

Question

在附加的代码(两个宏)中，如果我从“EcodeKeep”中调用“SortBy Ecode”，则代码永远不会结束。 (或者当我强制退出 excel 时至少不会在 5 分钟内结束)。

但是，如果我在运行“EcodeKeep”之前单独运行“SortByEcode”，它们每个都在 2 秒内运行。

电子表格中有超过 19K 行数据。此外，这是我第一次尝试在 VBA 中使用数组。

我究竟做错了什么？

Sub EcodeKeep()
     Dim i As Long
     Dim LastRow As Long

     Call SortByEcode  'Calling this sort macro here causes this code to run forever.

     Dim wks As Worksheet
     Set wks = rawData5            'Work in sheet("RawEquipHistory")
     LastRow = wks.Range("A" & Rows.Count).End(xlUp).Row
     StartTime = Timer

     Dim Ecode_arr() As Variant
          ReDim Ecode_arr(LastRow)
     Dim Results_arr() As String
          ReDim Results_arr(LastRow)

     For i = 0 To LastRow - 1  'Read data into Ecode_arr(i)
          Ecode_arr(i) = wks.Range("A" & i + 1)
     Next i

     wks.Range("AM1") = "ECODE KEEP"  'Add the header to "S1"
     For i = 0 To LastRow - 1
          If Ecode_arr(i + 1) <> Ecode_arr(i) Then
               Results_arr(i) = True
          Else
               Results_arr(i) = False
          End If
          wks.Range("AM" & i + 2) = Results_arr(i)
     Next i
End Sub

Sub SortByEcode()
 '  SORT sheet by E-Code (Column A)
      Dim LastRow As Long
     LastRow = ThisWorkbook.Sheets("RawEquipHistory").Range("A" & Rows.Count).End(xlUp).Row

     With ThisWorkbook.Sheets("RawEquipHistory").Sort               '  SORT sheet by E-Code(a)
          .SortFields.Clear
          .SortFields.Add Key:=Range("A1:A" & LastRow), Order:=xlAscending
          .SetRange Range("A1:AZ" & LastRow)
          .Header = xlYes
          .Apply
     End With
End Sub

Answer 1

您的循环不是无限的，只是效率低下。

除非您禁用了自动计算、应用程序/工作表事件和屏幕更新，否则每次写入单元格时，Excel 都会尝试跟上更改，但最终失败，会出现“(不响应)”，到那时，除了等待它之外，没有什么可做的了……这可能需要一段时间。

您可以在 上工作症状 并禁用自动计算、应用程序/工作表事件和屏幕更新 - 您的代码将更快地运行完成。

Application.Calculation = xlCalculationManual
Application.EnableEvents = False
Application.ScreenUpdating = False

当然，您会在循环完成后将它们重置为其原始值，并且如果过程中出现任何问题，您也要小心重置它们，即，每当您切换它们时，您都需要一个错误处理子例程。

或者您可以在 上工作根本原因 ，并稍微调整方法，将工作表操作减少到最低限度:一次读取，一次写入。 ...然后是否启用自动计算，每次写入单元格时 Excel 是否触发工作表事件并重新绘制屏幕都没有任何区别。

秘诀就是变体数组。你在这里有正确的想法:

 Dim Ecode_arr() As Variant
      ReDim Ecode_arr(LastRow)
 Dim Results_arr() As String
      ReDim Results_arr(LastRow)

但随后一一读取这些值需要付出代价:

 For i = 0 To LastRow - 1  'Read data into Ecode_arr(i)
      Ecode_arr(i) = wks.Range("A" & i + 1)
 Next i

不要费心调整数组的大小，让它们保持原样Variant包装 - 带有 Application.Transpose ，可以得到一维的Variant来自您的一列源范围的数组:

Dim ecodes As Variant
ecodes = Application.Transpose(wks.Range("A1:A" & LastRow).Value)

现在您可以迭代此数组以填充您的输出数组 - 但暂时不要写入工作表:将值一个一个写入工作表首先消除了对结果/输出数组的需要!

请注意，因为我们分配了 Boolean True 的值在一个分支和False在条件的另一个分支中，我们可以通过直接分配给条件的 bool 表达式来简化分配:

 ReDim results(LBound(ecodes), UBound(ecodes))

 Dim i As Long
 For i = LBound(results) To UBound(results) - 1
     results(i) = ecodes(i + 1) <> ecodes(i)
 Next

现在 results数组已填充，我们可以一次将其转储到工作表上 - 因为这是我们正在做的唯一工作表写入，所以 Excel 想要重新计算、引发事件和重新绘制并不重要:我们完成了!

wks.Range("AM2:AM" & i + 1).Value = results

注意:这些都不是经过测试的代码，当我调整偏移量时，可能会出现一个错误的错误(从 Range.Value 接收的数组将始终从 1 开始)。但你明白了:)